Cum să exportați rapid statisticile de vot dintr-un e-mail Outlook într-o foaie de lucru Excel

Dacă ați trimis un e-mail cu butoane de vot, după ce destinatarii vă trimit răspunsurile, poate doriți să numărați și să exportați statisticile de vot într-o foaie de lucru Excel. Deci, în această post, vă vom învăța cum să o realizați rapid.

Outlook este atât de puternic încât oferă chiar și o funcție de „votare”. Articolul meu anterior „Utilizarea cu pricepere a MS Outlook pentru vot” a învățat cum să-l folosească eficient. De asemenea, most de timp, după vot, puteți continua să exportați statisticile de vot într-o foaie de lucru Excel din anumite motive, cum ar fi doriți să imprimați statisticile. Dar Outlook nu acceptă acest lucru în mod implicit. Astfel, în cele ce urmează, vă vom învăța cum să realizați acest lucru ca un dop.

Exportați statisticile de vot într-un e-mail într-o foaie de lucru Excel

1. De la bun început, lansați aplicația Outlook.
2. Apoi ar trebui să apăsați butoanele tastei „Alt + F11” în fereastra principală a Outlook.
3. Apoi, în fereastra „Microsoft Visual Basic for Applications”, ar trebui să activați „Microsoft Excel Object Library”. Faceți clic pe „Instrumente” > „Referință”. Apoi, în caseta de dialog pop-up, bifați caseta de selectare din fața „Microsoft Excel Object Library” și apăsați „OK” în sfârșit.
4. După aceea, puteți introduce un modul nou sau puteți deschide unul care nu este utilizat.
5. Ulterior, copiați și lipiți următoarele coduri VBA în acest modul.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. După aceea, pentru un acces convenabil, ar fi bine să adăugați noua macrocomandă la Bara de instrumente Acces rapid.
6. În cele din urmă, puteți încerca.

• În primul rând, selectați un e-mail sursă care conține butoane de vot.
• Apoi faceți clic pe butonul macro din Bara de instrumente Acces rapid.
• După ce se termină rularea acestei macrocomenzi, puteți naviga la folderul local predefinit, în care veți vedea un nou registru de lucru Excel.
• Deschideți acest registru de lucru Excel. Acum veți vedea statisticile de vot, prezentate ca imaginea de mai jos:

Nimeni nu poate evita complet erorile Outlook

Deși Outlook este dotat cu o varietate de capabilități, nu există o astfel de caracteristică care să ne ajute să evităm erorile Outlook. Tot felul de factori pot cauza erori Outlook. De exemplu, dacă ieșiți adesea din Outlook necorespunzător, este posibil să suferiți corupție PST. Într-un astfel de scenariu, nu aveți de ales decât să folosiți câteva instrumente puternice pentru a vă salva fișierul PST, cum ar fi DataNumen Outlook Repair. A câștigat o mulțime de felicitări datorită ratei sale ridicate de recuperare.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv mdf corupt și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com