Slik kjører du raskt en spesifikk regel i alle e-postmapper med Outlook VBA

Som standard kan du bare kjøre en regel i én mappe om gangen. I denne artikkelen lærer vi deg hvordan du bruker et stykke VBA-kode for å kjøre en bestemt regel i alle postmapper.

Outlook tillater brukere å kjøre regelen manuelt. Du kan bare få tilgang til dialogboksen "Regler og varsler" og trykke "Kjør regler nå" -knappen. I den påfølgende dialogboksen velger du en bestemt regel og velger en mappe der du ønsker å kjøre denne regelen. Men hvis du vil kjøre en regel raskt i alle postmapper, kan du bruke følgende VBA-kode.

Kjør raskt en spesifikk regel i alle e-postmapper med Outlook VBA

Kjør raskt en spesifikk regel i alle e-postmapper

  1. Først og fremst, start Outlook-programmet ditt.
  2. Deretter trykker du på "Alt + F11" i hovedvinduet i Outlook.
  3. Neste i det nye vinduet "Microsoft Visual Basic for Applications" bør du åpne en modul som ikke er i bruk.
  4. Kopier deretter VBA-koden nedenfor til dette modulvinduet. I tillegg bør du endre noen linjer basert på din egen sak, for eksempel regelnavnet.
Sub RunSpecificRule_AllMailFolders()
    Dim objStores As Outlook.Stores
    Dim objStore As Outlook.Store
    Dim objPSTFile As Outlook.Folder
    Dim objFolders As Outlook.folders
    Dim objFolder As Object

    Set objStores = Outlook.Application.Session.Stores
 
    'Process all Outlook PST files in your Outlook
    For Each objStore In objStores
        Set objPSTFile = objStore.GetRootFolder
        For Each objFolder In objPSTFile.folders
            Call ProcessFolders(objFolder)
        Next
    Next

    MsgBox "Complete!", vbExclamation + vbOKOnly, "Run Rule "
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objRules As Outlook.Rules
    Dim objRule As Outlook.Rule
    Dim objSubfolder As Outlook.Folder

    Set objRules = Outlook.Application.Session.DefaultStore.GetRules
    'Change the rule name as per your actual case
    Set objRule = objRules.Item("Move Mails to Temp")
 
    On Error Resume Next
    'Only work on non-empty Mail folder
    If objCurrentFolder.Items.count > 0 And objCurrentFolder.DefaultItemType = olMailItem Then
       With objRule
            .Enabled = True
            .Execute ShowProgress:=True, Folder:=objCurrentFolder, IncludeSubfolders:=True
       End With
    End If
 
    'Process subfolders recursively
    If objCurrentFolder.folders.count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

VBA-kode - Kjør en spesifikk regel i alle e-postmapper

  1. Etter det bør du sjekke Outlook-makroinnstillingene, og sikre at makro er tillatt.
  2. Til slutt kan du prøve deg frem.
  • Bare klikk på "RunSpecificRule_AllMailFolders"-underrutinen.
  • Trykk deretter på F5-tasten for å utløse denne koden.
  • Deretter vil makroen kjøre umiddelbart.
  • Etter at den er fullført, vil du få en melding, som følgende skjermbilde. Det viser til at regelen er ferdig.Kjør fullført

Se opp for ondsinnede makroer

Som vi alle vet, har ondsinnede e-poster blitt stadig mer utbredt. Slike e-poster inneholder ofte ondsinnede makroer. Derfor, hvis du setter Outlook-makrosikkerhetsnivået til lavt, må du passe deg for skjulte virus og skadelig programvare. Dessuten er det klokt å få tak i et kraftig PST-fixverktøy, som f.eks DataNumen Outlook Repair. Det er i stand til reparere PST fil og trekk ut maksimal data for deg uten å svette.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert gjenopprette mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.