Slik fjerner du raskt dupliserte Outlook-elementer i en mappe via VBA

Outlook-løsninger September 29, 2025

Hvis du ønsker å fjerne duplikatelementene i Outlook, vil det være ganske vanskelig å søke og fjerne én etter én. Dette innlegget vil lære deg hvordan du raskt kan fullføre det med Outlook VBA.

I min forrige artikkel - "Hvordan raskt finne og fjerne dupliserte e-poster i Outlook”, kan du lære et triks for å finne og fjerne dupliserte e-poster, som først sorterer e-postene etter emne, deretter etter mottatt tid og deretter etter vedlegg for å finne ut de dupliserte elementene og til slutt velger du de dupliserte og trykker på “Slett”-tasten. Selv om denne metoden tilsynelatende er litt mer praktisk, men den er langt mer plagsom sammenlignet med å bruke Outlook VBA. Ved hjelp av følgende VBA-koder kan du raskt fjerne de dupliserte elementene med ett klikk, uansett e-post, oppgaver, kontakter eller avtaler. Les nå videre for å få kodene i detalj.

Fjern raskt dupliserte Outlook-elementer i en mappe via VBA

Fjern dupliserte Outlook-elementer i en mappe

  1. For å begynne, start Outlook-programmet ditt.
  2. Trykk deretter på "Alt + F11"-tastene.
  3. I det påfølgende VBA-redigeringsvinduet, dobbeltklikk for å åpne en modul som er i bruk, eller sett inn en ny modul direkte ved å "Sett inn" > "Modul".
  4. Kopier og lim deretter inn følgende VBA-koder i modulen.
Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

VBA-koder - Fjern raskt dupliserte Outlook-elementer i en mappe

  1. Deretter signerer du denne makroen digitalt og endrer Outlook-makrosikkerhetsnivået til lavt.
  2. Senere kan du kjøre dette nye VBA-prosjektet. Klikk direkte på "Kjør"-ikonet i verktøylinjen.kjøre denne makroen
  3. Deretter må du velge en mappe der du vil fjerne dupliserte elementer.Velg en mappe
  4. Til slutt vil de dupliserte elementene i den valgte mappen bli slettet med en gang.

Beskytt sårbare PST-data

På grunn av det faktum at PST-filen er utsatt for korrupsjon, bør du derfor bruke mye arbeid på å beskytte PST-filen din. Du bør for eksempel forhindre at Outlook lukkes på feil måte. Videre må du forberede en robust Outlook-fiks verktøy, for eksempel DataNumen Outlook Repair som vil kunne redde din PST i tide.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert gjenopprette SQL Server og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.