Slik skriver du raskt ut alle bildevedlegg av en Outlook-e-post på bare én side

For å spare skriverblekk og papir, ønsker noen brukere å skrive ut alle bildene vedlagt i en e-post på kun én side, i stedet for ett bilde per side. Nå vil denne artikkelen dele et middel for å realisere det.

Som vi alle vet, er utskrift av bilder ganske sløsing med skriverblekk. For å spare skriverblekk og papir, foretrekker du kanskje å skrive ut mange bildevedlegg på samme side i stedet for å skrive ut bilder på separate sider. Selv om Outlook ikke tilbyr en slik funksjon, kan du fortsatt oppnå det på følgende måter.

Skriv ut alle bildevedlegg av en Outlook-e-post kun på én side

1. For å begynne, start Outlook-applikasjonen din.
2. Trykk deretter på "Alt + F11"-tastene i Outlook-vinduet.
3. Deretter kommer du inn i vinduet «Microsoft Visual Basic for Applications», der du først må aktivere «Microsoft Word Object Library».
4. Etter det må du åpne en modul som ikke er i bruk.
5. Deretter kopierer og limer du inn følgende VBA-kode i denne modulen.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Senere kan du gå tilbake til e-postlisten. Velg eller åpne en e-post hvis bildevedlegg du vil skrive ut.
7. Deretter utløser du denne makroen. I det gjeldende makrovinduet trykker du bare på "F5"-tasten eller klikker på "Kjør"-ikonet i verktøylinjen.
8. Til slutt, når makroen er ferdig å kjøre, vil alle bildevedlegg av kilde-e-posten bli skrevet ut på én side, som følgende skjermbilde:

Håndtere ødelagte Outlook-filer

Med flere og flere data lagret i Outlook, blir Outlook-filen stadig mer sårbar. Det kan bli kompromittert på grunn av ulike interne og eksterne faktorer. Dessuten er det vanskelig å forutsi korrupsjon i Outlook. Så det du kan gjøre er å sikre umiddelbar og effektiv redning når du møter Outlook-korrupsjon. For eksempel må du holde en spesialisert PST reparasjon verktøy, som DataNumen Outlook Repair i nærheten. Det vil skanne og gjenopprette skadede filer som en lek.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert gjenopprette Sql Server og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med