Slik finner du raskt avsnitt med én setning i Word-dokumentet ditt

I dette innlegget vil vi vise deg den raske måten å finne alle avsnitt på én setning i Word-dokumentet ditt via VBA.

Noen dokumenter kan nå og da ha svært spesifikke krav til formatering og strukturer. For eksempel kan det hende du ikke har lov til å ha avsnitt med bare én setning. Disse avsnittene er ikke vanskelige å gjenkjenne, men det tar tid, spesielt det er et langt dokument.

I dag vil vi tilby deg den raske måten å spesifisere alle avsnitt med én setning i dokumentet ditt.

Finn alle avsnitt med én setning i ett dokument

1. For det første teller Word en punktum som en setning. Så hvis det er ord som "Mr." eller "Ms.", Word anser det som en setning. For å utelukke en slik distraksjon må du erstatte "Mr." med "Mr". Og når du er ferdig med å finne avsnitt i en enkelt setning, kan du endre dem tilbake. For å erstatte ord, kan du se denne lenken: Hvordan finne og erstatte flere elementer i Word-dokumentet ditt
2. For det andre, trykk "Alt + F11" for å utløse VBA-editor.
3. Klikk deretter på "Normal" prosjekt.
4. Klikk på "Sett inn"-fanen på menylinjen og velg "Modul" på rullegardinmenyen.
5. Dobbeltklikk deretter på modulen for å åpne den.
6. Lim inn følgende koder på modulen:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Sist men ikke minst, klikk på "Kjør"-knappen eller trykk på "F5".

Du vil motta en slik meldingsboks som forteller deg at jobben er gjort.

Finn alle avsnitt med én setning i flere dokumenter

1. Til å begynne med må du legge alle måldokumentene i en mappe.
2. Installer og kjør deretter makroen nedenfor:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. I "Bla gjennom"-vinduet åpner du, velg mappen der du oppbevarer dokumenter og klikk "OK".

Makroen vil da fremheve alle avsnitt med én setning og la dokumenter være åpne. Hvis et dokument ikke inneholder et avsnitt med én setning, vil det bli lukket. Dessuten er det en meldingsboks som angir antall avsnitt med én setning i hvert dokument.

Håndtere hendelse med tap av data

Brukerfeil og plutselig strømbrudd kan føre til at Word dør. Mens et kollapset Word kan ikke bare påvirke det daglige arbeidet, men også føre til doc skadeDette er på ingen måte den mest irriterende delen av en datakatastrofe. Det er bedre å få et reparasjonsverktøy til å gjenopprette data umiddelbart.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert gjenopprette Excel og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med