Hvordan raskt eksportere total tid brukt på Outlook-avtaler i hver fargekategori

Hvis du ønsker å lage en rapport om den totale tiden du bruker på avtalene i hver fargekategori, kan du bruke metoden introdusert i denne artikkelen. Det kan hjelpe deg å oppnå dette på rask tid uten å måtte telle manuelt.

Mange brukere er vant til å logge mesteparten av aktivitetene sine i Outlook-kalenderen. For å administrere og differensiere dem enklere, tildeler de også kategorier til hver av dem. I dette tilfellet ønsker noen brukere å generere en rapport som viser den totale tiden brukt på kalenderelementene i hver fargekategori. Det er uten tvil vanskelig å telle og legge inn manuelt. Derfor skal vi her dele en måte som kan utføre denne oppgaven med et enkelt klikk.

Eksporter total tid brukt på avtaler i hver fargekategori

1. For det første, start Outlook-applikasjonen.
2. Deretter, etter å ha gått inn i Outlook-vinduet, kan du trykke på "Alt + F11" -tastene.
3. Deretter får du tilgang til "Microsoft Visual Basic for Applications"-vinduet.
4. Deretter må du aktivere «Microsoft Excel Object Library». Du kan klikke på «Verktøy» > «Referanse» for å gjøre det.
5. Deretter bør du finne og åpne en modul som ikke er i bruk.
6. Etter det må du kopiere følgende VBA-kode inn i denne modulen.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Til slutt kan du utløse denne makroen, uansett ved å klikke på "Kjør"-ikonet i verktøylinjen eller trykke på "F5"-tasten.
8. Deretter vil du bli bedt om å velge en spesifikk kalender.
9. Etter at du har valgt og trykket "OK", vil makroen fortsette å kjøre. Etter at den er ferdig, vil det være en ny Excel-fil som vises i bakgrunnen.
10. Du kan få tilgang til den. Det vil se ut som følgende skjermbilde:

Hold øye med potensielle trusler rundt Outlook

Outlook-brukere bør passe på alle potensielle risikoer, inkludert ukjente e-postvedlegg, innebygde koblinger og menneskelige feil. Ellers kan Outlook bli ødelagt når som helst. Det er også nødvendig å ta regelmessige sikkerhetskopier av Outlook-data og ha et spesialisert reparasjonsverktøy. DataNumen Outlook Repair er et av de mest anbefalte reparasjonsverktøyene. Det kan reparere Outlook problemer på et blunk.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert skadet mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med