Slik eksporterer du raskt en Outlook-mappe med alle undermapper og elementer til en Windows-mappe

Noen ganger vil du kanskje batcheksportere en Outlook-mappe med alle undermapper og elementer til en Windows-mappe. Denne artikkelen vil lære deg en slik metode som bruker Outlook VBA.

Når du ønsker å eksportere en Outlook-mappe til lokal stasjon med alle elementer i samme mappestruktur, hvis du velger å lagre og eksportere manuelt, vil det ta deg mye tid. Derfor, hvorfor tyr du ikke til andre midler, for eksempel eksportverktøy eller VBA-koder? Her vil vi avduke et slikt stykke VBA-kode for deg. Det vil tillate deg å oppnå det som en lek.

Eksporter alle undermapper og elementer i en Outlook-mappe til en Windows-mappe

1. Start Outlook-programmet helt fra starten av.
2. Deretter trykker du på "Alt + F11" i hovedvinduet i Outlook.
3. Deretter vil vinduet "Microsoft Visual Basic for Applications" dukke opp.
4. Deretter må du åpne en tom modul og kopiere følgende VBA-koder inn i den.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Etter det må du sørge for at Outlook tillater makroer i makroinnstillingene.
6. Til slutt kan du prøve.

• Først tilbake til det nye makrovinduet.
• Klikk deretter inn i "ExportFolderWithAllItems"-underrutinen.
• Trykk deretter på F5-tasten for å kjøre denne makroen.
• Etter det må du velge en bestemt mappe.
• Til slutt, når du får en melding som sier "Fullfør", kan du få tilgang til den forhåndsdefinerte lokale mappen. Du vil finne at alle elementene er lagret i samme mappestruktur.

Forhindre tap av data fra Outlook-krasj

Du har kanskje opplevd at Outlook har krasjet mange ganger. Som oftest, etter en omstart, vil Outlook fungere som normalt. Det kan imidlertid også hende at PST-filen vår blir ødelagt. Da bør du prøve å gjenopprette PST-dataene dine, for eksempel ved å bruke et erfarent verktøy som DataNumen Outlook Repair. Det er i stand til fikse Outlook feil og trekke ut data fra kompromittert PST-fil uten å svette.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert SQL Server reparasjon og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med