Slik eksporterer du raskt alle bildevedlegg av en Outlook-e-post til en PDF filet

Outlook-løsninger September 29, 2025

Hvis du raskt vil eksportere alle bildevedlegg av en Outlook-e-post til en PDF fil, kan du bruke metoden introdusert i denne artikkelen. Den bruker et stykke VBA-kode for å realisere slik "eksport" på kort tid.

Noen ganger kan det være lurt å kombinere mange bilder til en PDF fil, som å eksportere alle bildevedlegg av en e-post til en PDF fil. Det høres litt vanskelig ut. Men i det følgende viser vi en metode som raskt kan oppnå dette uten problemer.

Eksporter raskt alle bildevedlegg av en Outlook-e-post til en PDF filet

Eksporter alle bildevedlegg av en e-post til en PDF filet

  1. For somtart, start Outlook-programmet som vanlig.
  2. Trykk deretter på "Alt + F11"-tastene i hovedvinduet i Outlook.
  3. Deretter vil du se popup-vinduet "Microsoft Visual Basic for Applications".
  4. I dette vinduet må du få tilgang til en modul som ikke er i bruk.
  5. Deretter kan du kopiere og lime inn følgende VBA-kode i denne modulen.
Sub ExportAllImageAttachmentsIntoPdfFile()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objWordApp As Word.Application
    Dim objTempDocument As Word.Document
    Dim strImage As String
    Dim objInlineShape As Word.InlineShape
    Dim strPDF As String
 
    Set objSourceMail = Application.ActiveInspector.currentItem
 
    If Not (objSourceMail Is Nothing) Then
 
       Set objWordApp = CreateObject("Word.Application")
       Set objTempDocument = objWordApp.Documents.Add
       objWordApp.Visible = True
       objTempDocument.Activate
 
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                           objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       strImage = Dir(strTempFolder & "*.*", vbNormal)

       Do Until Len(strImage) = 0
          With Selection
               .InlineShapes.AddPicture (strTempFolder & strImage)
               .TypeParagraph
               .Collapse Direction:=wdCollapsEnd
               .ParagraphFormat.Alignment = wdAlignParagraphCenter
               .TypeParagraph
          End With
          strImage = Dir()
       Loop

       For Each objInlineShape In objTempDocument.InlineShapes
           objInlineShape.Select
           Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
           objInlineShape.ScaleHeight = 50
           objInlineShape.ScaleWidth = 50
       Next
 
       'Change the path to save the PDF file
       strPDF = "E:\Image Attachments.pdf"
 
       'Export the temp Word document as a PDF file
       objTempDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF
  
       objTempDocument.Close False
       objWordApp.Quit
 
       MsgBox "Complete!" 
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

VBA-kode - Eksporter alle bildevedlegg av en e-post til en PDF filet

  1. Etter det kan du lukke det gjeldende vinduet.
  2. Senere kan du gå til "Fil"> "Alternativer"> "Hurtigtilgangsverktøylinje". Nå kan du legge til den nye makroen til Quick Access Toolbar.
  3. Til slutt kan du prøve denne makroen.
  • Først åpner du en e-post hvis bildevedlegg du vil eksportere til en PDF filen.
  • Klikk deretter på makroknappen i verktøylinjen for hurtigtilgang.
  • Når makroen er fullført, får du en melding.
  • Etter det kan du gå til den forhåndsdefinerte lokale mappen for å finne en PDF fil, som inneholder alle bildene vedlagt den åpne e-posten.eksportert PDF filet

Hent kompromitterte Outlook-data

Hvis Outlook blir ødelagt, bør du prøve å gjenopprette de skadede dataene. I dette tilfellet kan du først prøve det innebygde reparasjonsverktøyet – Scanpst. Forutsatt at det ikke er opp til oppgaven med å reparere Outlook-fil, kan du også ta hjelp av eksterne verktøy, som f.eks. DataNumen Outlook Repair. Den er god til å gjenopprette skadet Outlook filer med minimalt med korrupsjon.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert mdf reparasjon og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.