Slik eksporterer du raskt detaljene til alle medlemmer i en Outlook-kontaktgruppe til Excel

Som standard kan du bare se medlemsnavn og e-postadresser i en kontaktgruppe. Hvis du ønsker å få medlemmenes andre detaljer, kan du bruke måten introdusert i denne artikkelen.

Når du dobbeltklikker på en kontaktgruppe for å åpne den, i vinduet, kan du bare se gruppemedlemmenes navn og e-postadresser. Du kan ikke få medlemmenes andre detaljer, som firma, stillingstittel, telefonnummer eller forretningsadresse osv. Generelt, for å få disse detaljene, må du finne kontaktene som tilsvarer medlemmene i Kontakter-mappen manuelt. Det er for plagsomt. Her vil vi vise deg et stykke VBA-kode, som raskt kan eksportere disse detaljene til en Excel-arbeidsbok.

Eksporter detaljene for alle medlemmer i en kontaktgruppe til Excel

1. Til start med, start Outlook-applikasjonen.
2. Deretter bør du trykke "Alt + F11" tastesnarveier i hovedvinduet i Outlook.
3. Neste i det nye "Microsoft Visual Basic for Applications"-vinduet må du åpne en modul som ikke er i bruk eller sette inn en ny modul direkte.
4. Deretter kopierer og limer du inn følgende VBA-kode i denne modulen.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Etter det, for praktisk sjekk, kan du legge til det nye VBA-prosjektet til Quick Access Toolbar eller bånd.
6. Sett senere Outlook-makrosikkerhetsnivået til lavt.
7. Til syvende og sist kan du prøve.

• Velg først en kontaktgruppe.
• Trykk deretter på makroknappen i verktøylinjen for hurtigtilgang eller på båndet.
• Umiddelbart vil makroen kjøre.
• Når den er ferdig, vil du få en melding om "Fullfør!"
• Etter det kan du gå til den forhåndsdefinerte destinasjonsmappen, der du kan finne en ny Excel-fil.
• Åpne den, du vil se gruppemedlemmenes kontaktinformasjon som følgende skjermbilde:

Ikke få panikk i møte med Outlook-problemer

Ingen er villige til å godta noen Outlook-problemer, uansett popup-feilmelding eller korrupte Outlook data fil. Derfor vil brukere ha en tendens til å få panikk når de kommer over Outlook-problemer. Skal du i så fall beholde roen, bør du ha to nødvendigheter i hånden. Den ene er gjeldende sikkerhetskopiering av Outlook-data. Den andre er potent Outlook-fixprogramvare, som DataNumen Outlook Repair.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert sql utvinning og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med