Slik konverterer du raskt alle innebygde bilder til vedlegg i Outlook-e-posten din

Hvis du raskt vil endre alle bildene som er innebygd i meldingsteksten til e-postvedlegg, trenger du ikke å fjerne og legge ved på nytt manuelt. Du kan bare bruke VBA-koden som vises i denne artikkelen.

Noen ganger kan det hende du ønsker å slå alle innebygde bilder om til vedlegg. For mange bilder i meldingsteksten vil for eksempel avbryte lesingen av tekstene i brødteksten. Derfor vil du fjerne dem fra e-postteksten og legge dem til som vedlegg i stedet. Selvfølgelig kan du gjøre dette manuelt. Men det må være lettere hvis noen verktøy eller VBA-koder kan få dette på en gang. Her vil vi avduke en slik VBA-kode for deg.

Konverter raskt alle innebygde bilder til vedlegg

1. For det første, start Outlook-programmet ditt.
2. Deretter kan du bytte til «Utvikler»-fanen og trykke på «Visual Basic»-knappen.
3. Deretter kommer du inn i Outlook VBA-redigeringsvinduet.
4. Deretter må du kopiere følgende VBA-kode til en tom modul.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Etter det bør du bekrefte at Outlook er satt til å tillate makroer.
6. Eventuelt, hvis du ofte trenger dette, bør du legge til den nye makroen til Quick Access Toolbar for fremtidig praktisk sjekk.
7. Etterhvert kan du prøve. Velg eller åpne en e-post, og kjør deretter makroen ved å klikke på den nye makroknappen i hurtigtilgangsverktøylinjen.
8. Umiddelbart vil alle de innebygde bildene bli endret til vedlegg som følgende skjermbilde:

Triks for å beskytte dine verdifulle Outlook-data

Som vi alle vet, er Outlook PST-fil den samme sårbare som vanlige filer, for eksempel Word-dokumenter eller Excel-regneark. Derfor bør du fortsette å se opp for alle risikoer rundt PST-filen din, som virus eller feilaktig håndtering. Så du må ta regelmessige sikkerhetskopier av PST-filen din. Dessuten, hvis du har råd til det, er det lurt å holde en robust Outlook reparasjon verktøy hendig, som DataNumen Outlook Repair.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert gjenopprette mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med