Slik legger du raskt ved den sist endrede filen i en Windows-mappe til Outlook-e-posten din

Noen ganger vil du kanskje raskt finne og legge ved den sist endrede filen i en bestemt Windows-mappe til en Outlook-e-post. I dette tilfellet kan du bruke metoden introdusert i denne artikkelen.

Noen brukere ønsker at Outlook raskt skal finne ut og legge til den sist endrede filen i en Windows-mappe i en e-post, for eksempel den sist opprettede, endrede eller lagrede filen. Outlook tilbyr imidlertid ikke en slik direkte og innebygd funksjon. Derfor vil vi i det følgende vise et stykke VBA-kode som kan realisere dette med letthet.

Legg ved den sist endrede filen i en Windows-mappe til e-post

1. Helt i begynnelsen bør du starte Outlook-applikasjonen.
2. Så, etter at du har kommet inn i hovedvinduet i Outlook, kan du trykke på "Alt + F11" -tastene.
3. Deretter får du tilgang til Outlook VBA-redigeringsvinduet.
4. Deretter bør du finne og åpne en modul som ikke er i bruk.
5. Og kopier og lim inn følgende VBA-kode i dette modulvinduet.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Etter det kan du gå ut av det gjeldende VBA-redigeringsvinduet og fortsette å legge til den nye makroen til hurtigtilgangsverktøylinjen eller båndet til meldingsvinduet.
7. Senere må du endre Outlook-makrosikkerhetsnivået til lavt.
8. Til slutt kan du prøve deg frem.

• Først, opprett og komponer en ny Outlook-e-post som vanlig.
• Trykk deretter på makroknappen i verktøylinjen for hurtigtilgang, som bildet nedenfor:
• Deretter må du velge en kilde for Windows-mappe og trykke "OK".
• Hvis det er en slik fil i den valgte Windows-mappen, får du en melding som følgende skjermbilde:
• Når du trykker "Ja", vil denne filen legges ved med en gang.

Løs Outlook-problemer så snart som mulig

Når du støter på Outlook-problemer, anbefales det å løse dem så snart som mulig. I denne situasjonen bør du forberede en robust Outlook-fiks verktøy på forhånd, som f.eks DataNumen Outlook Repair. Den er i stand til å fikse PST-feil og redde Outlook-dataene dine effektivt.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert ødelagt mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med