Slik trekker du ut alle mottakere raskt fra flere Outlook-meldingsfiler (.msg).

Noen brukere vil raskt trekke ut alle mottakerne fra flere Outlook-meldingsfiler som er lagret fra Outlook-e-poster. Nå, denne sost vil se på dette for å dele en rask tilnærming.

For å trekke ut mottakerne fra en enkelt Outlook-meldingsfil, kan du bare dobbeltklikke for å åpne den og deretter kopiere mottakerne i det åpnede meldingsvinduet. Men hvis du trenger å håndtere en gruppe Outlook-meldingsfiler, er den manuelle metoden ikke effektiv nok. Dermed kan du se etter en mye mer effektiv måte. Her vil vi introdusere en slik for deg. Les videre for å få detaljene.

Trekk ut alle mottakere fra flere Outlook-meldingsfiler (.msg).

1. For somtart, få tilgang til Outlook VBA editor i henhold til "Hvordan kjøre VBA-kode i Outlook".
2. Deretter kopierer og limer du inn følgende VBA-kode i en tom modul.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Flytt deretter markøren i den første subrutinen.
4. Deretter klikker du på "Kjør"-knappen eller trykker på "F5"-tasten.
5. I popup-dialogboksen velger du deretter Windows-mappen som inneholder Outlook-kildefilene (.msg).
6. Etter å ha valgt, klikk "OK" for å la makroen fortsette å kjøre.
7. Når makroen er ferdig, vises en melding som viser alle utpakkede mottakeres e-postadresser, som vist på følgende skjermbilde.

Beskytt Outlook-dataene dine mot fare

Outlook-data er riktignok utsatt for korrupsjon. Derfor er det en ganske tung oppgave å beskytte Outlook-data. Det krever at du holder ut med å lage regelmessig sikkerhetskopiering for Outlook-data. Hvis det er mulig, er det også fornuftig og anbefalt å utarbeide en erfaren og profesjonell Outlook PST reparasjon verktøy, som DataNumen Outlook Repair, slik at du kan få umiddelbar og rettidig redning i tilfelle Outlook-korrupsjon.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert gjenopprette Sql Server og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med