Slik bruker du automatisk forskjellige skriftfarger for å svare og videresende e-poster med Outlook VBA

Outlook-løsninger September 29, 2025

Som standard kan du ikke la Outlook automatisk bruke forskjellige skriftfarger for å svare på og videresende e-poster. Hvis du har et slikt behov, kan du derfor lese dette innlegget for å lære en smart tilnærming.

Outlook tillater deg bare å spesifisere en skrifttype som brukes til både å svare på og videresende e-poster. Du kan gå til "Fil"> "Alternativer". Gå deretter til "E-post"-fanen i "Outlook-alternativer" og klikk på "Brevpapir og skrifter ..." -knappen. I det påfølgende vinduet kan du se "Skrift"-knappen i "Svare eller videresende meldinger". Klikk på den, og deretter kan du angi en bestemt skriftfarge for å svare og videresende e-poster.

Endre skrift i svar eller videresending av meldinger

Imidlertid håper mange brukere å bruke forskjellige skriftfarger for å svare eller videresende e-poster. Selv om Outlook ikke gir noen direkte funksjoner for dette, kan det fortsatt realiseres med VBA-kode. Nå, les videre for å få en slik del av VBA-kode.

Auto Bruk forskjellige skriftfarger for å svare og videresende e-poster

  1. For å begynne, start Outlook-applikasjonen.
  2. Deretter utløser du VBA-editoren med referanse til "Hvordan kjøre VBA-kode i Outlook".
  3. Deretter, i henhold til "Slik legger du til en objektbibliotekreferanse i VBA«, legg til referansen til «MS Word-objektbibliotek».
  4. Kopier deretter følgende kode inn i "ThisOutlookSession" -prosjektet.
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

VBA-kode - Bruk forskjellige skriftfarger automatisk for å svare og videresende e-poster

  1. Deretter starter du Outlook på nytt for å aktivere denne makroen.
  2. Endelig kan du prøve.
  • Velg eller åpne en e-post.
  • Klikk deretter på "Svar"-knappen. Når du svarer på e-post, kan du skrive inn noen ord i brødteksten. Skriftfargen må være rosa."Rosa" skrift i "Svar"
  • Eller klikk på "Svar alle"-knappen. Skriv inn ord i brødteksten i den nye «svarer alle»-posten. Skriftfargen er sikkert grønn."Grønn" skrift i "Svar alle"
  • På samme måte klikker du på "Videresend"-knappen. I videresendingsposten vil de nye ordene vises i blått."Blue" Font i "Forward"

Bruk pålitelig programvare

I tilfelle av Outlook-korrupsjonDe fleste brukere har en tendens til å ty til Outlook-gjenopprettingsprogramvare. Det finnes et stort antall slike programmer tilgjengelig på markedet. Og noen av dem er til og med gratis. Likevel bør du være forsiktig med de fra ukjente kilder, da de kan gjøre situasjonen verre og verre. Du bør benytte deg av et pålitelig og erfarent verktøy, som DataNumen Outlook Repair.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert ødelagt sql og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.