Slik sletter du alle lesebekreftelser i Outlook

For å bekrefte at mottakerne har lest e-posten din, kan du be om lesebekreftelse når du skriver e-posten. I denne situasjonen kan postkassen din være fylt med slike lesebekreftelser. Nå, denne sost vil lære deg hvordan du batchsletter dem permanent.

Etter å ha lest artikkelen "Slik sletter du alle leveringskvitteringer i Outlook", kan du tenke på tilnærmingen til å masseslette alle lesebekreftelser. Faktisk er den åpenbare forskjellen mellom de to typene kvitteringer emnene deres. Leveringskvittering inneholder "Levert" i emne, men lesekvittering inneholder "Lest" i stedet. Derfor kan du bruke samme måte å batchslette alle lesekvitteringer. I det følgende vil vi lære deg de konkrete trinnene i detalj.

Batch Slett alle lesebekreftelser

1. I begynnelsen, start Outlook.
2. Gå deretter til Outlook VBA editor via "Alt + F11" i henhold til "Hvordan kjøre VBA-kode i Outlook".
3. Deretter åpner du en tom modul i det nye vinduet og legger inn følgende kode i den.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Klikk deretter inn i den første subrutinen.
5. Til slutt trykker du på "F5"-tasten.
6. Med en gang vil makroen fungere for å slette alle lesebekreftelser fra Outlook.
7. Når det er ferdig, vil du få en melding om resultatet, som skjermbildet nedenfor.
8. For øyeblikket kan du sjekke e-postmappene dine. Alle lesebekreftelser er borte.

Forsvar Outlook-data

Selv om Outlook-filen riktignok er utsatt for korrupsjon, kan vi iverksette tiltak for å beskytte den. For eksempel bør vi holde Outlook-filen i liten størrelse, beskytte den mot ondsinnede faktorer og sikkerhetskopiere den med jevne mellomrom. Sist, men ikke minst, bør du forberede et kraftig eksternt PST-reparasjonsverktøy, som DataNumen Outlook Repair. Det vil ha stor innvirkning på reparasjonen korrupte Outlook filen.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert sql reparasjon og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med