Slik angir du automatisk forskjellig påminnelsestid for Outlook-møter i forskjellige fargekategorier

Hvis du klassifiserer Outlook-møter etter fargekategorier og ønsker å angi forskjellig påminnelsestid for møter i forskjellige fargekategorier, kan du referere til denne artikkelen. Her skal vi lære deg å realisere det med Outlook VBA.

For eksempel deler du møter inn i to grupper. Den ene er i fargekategorien «Ekstern», siden møtestedet er for langt unna, og den andre er i fargekategorien «På stedet», siden stedet er rett her. Nå ønsker du at Outlook automatisk skal kunne sette påminnelsestiden for «eksternt møte» til 1 time før start og «på stedet» til 15 minutter før start. Med tanke på dette kravet vil vi nedenfor dele en rask metode.

Angi automatisk annen påminnelse for møter i forskjellige fargekategorier

1. Start Outlook-applikasjonen til å begynne med.
2. Deretter trykker du på "Alt + F11"-tastene for å få tilgang til VBA-redigeringsvinduet.
3. Deretter, i det påfølgende vinduet, kopierer og limer du inn VBA-koden nedenfor i "ThisOutlookSession" -prosjektet.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Senere må du klikke på subrutinen «Application_Startup» og trykke på «F5»-tasten for å kjøre denne makroen.
5. Siden da, hver gang når et nytt møte legges til standardkalenderen eller du endrer et eksisterende møte, vil Outlook automatisk sjekke møtekategoriene og automatisk stille inn det forskjellige påminnelsestidspunktet.

Eliminer Outlook-feil

Ulike problemer kan oppstå med Outlook fra tid til annen. Derfor er det ekstremt viktig for brukere å lære hvordan de skal håndtere Outlook-problemer. For det første bør du ta regelmessige sikkerhetskopier av Outlook-data. Dessuten, hvis det er rimelig, anbefales det å ha en kraftig Outlook reparasjon verktøy i nærheten, som f.eks DataNumen Outlook Repair. Den kan skanne PST-filen din for å finne ut Outlook-problemer og deretter løse dem med letthet.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert sql utvinning og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med