Slik fjerner du automatisk e-postadressene til originale avsendere og mottakere når du videresender en Outlook-e-post

Outlook-løsninger September 29, 2025

Når du videresender en e-post i Outlook, vil e-postadressene til den opprinnelige avsenderen og mottakerne bli inkludert i meldingsteksten. Av sikkerhetshensyn bør du nå fjerne disse adressene. Dette innlegget vil lære deg hvordan du lar Outlook gjøre dette automatisk.

I mange tilfeller må du videresende noen e-poster til noen andre. Som standard vil overskriften til den opprinnelige e-posten vises i brødteksten til videresending av e-post. Og overskriften vil inkludere e-postadressene til den opprinnelige avsenderen og mottakerne. På dette tidspunktet, for sikkerhet eller personvern, kan det være lurt å fjerne disse e-postadressene. Likevel er det for kjedelig å fjerne dem manuelt. Derfor vil vi her veilede deg for å få Outlook til å automatisk utføre denne oppgaven på vegne av deg.Fjern automatisk e-postadressene til opprinnelige avsendere og mottakere når du videresender en Outlook-e-post

Fjern automatisk e-postadressene til originale avsendere og mottakere når du videresender en e-post

  1. For en start, start Outlook.
  2. Deretter trykker du på "Alt + F11"-tastene for å få tilgang til VBA-editor.
  3. Deretter kopierer du følgende VBA-kode inn i "ThisOutlookSession" -prosjektet.
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objRegExp As Object
    Dim strHTMLBody As String
 
    Forward.Display
    strHTMLBody = Forward.HTMLBody
 
    'Find email addresses in the body via Regular Expression
    Set objRegExp = CreateObject("vbscript.RegExp")
    With objRegExp
        .Pattern = "(?:[a-z0-9!#$%&'*+/=?^_`{|}~-]+(?:\.[a-z0-9!#$%&'*+/=?^_`{|}~-]+)*|""(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21\x23-\x5b\x5d-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])*"")@(?:(?:[a-z0-9](?:[a-z0-9-]*[a-z0-9])?\.)+[a-z0-9](?:[a-z0-9-]*[a-z0-9])?|\[(?:(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.){3}(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?|[a-z0-9-]*[a-z0-9]:(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21-\x5a\x53-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])+)\])"
        .IgnoreCase = True
        .Global = True
    End With
 
    'Remove email addresses
    If objRegExp.Test(strHTMLBody) Then
       Set objFoundResults = objRegExp.Execute(strHTMLBody)
       For i = 1 To objFoundResults.Count
           Forward.HTMLBody = Replace(Forward.HTMLBody, objFoundResults.Item(i - 1).Value, "")
       Next
    End If
 
    'Remove useless characters
    Forward.HTMLBody = Replace(Forward.HTMLBody, "[mailto:]", "")
    Forward.HTMLBody = Replace(Forward.HTMLBody, "()", "")
End Sub

Sett VBA-kode inn i ThisOutlookSession Project

  1. Deretter starter du Outlook-programmet på nytt for å aktivere denne nye makroen.
  2. Til slutt kan du ta et skudd:
  • Velg eller åpne en e-post.
  • Klikk deretter på "Videresend"-knappen i "Svar"-gruppen.Videresend E-post
  • Til slutt vil en ny videresendings-e-post vises, der e-postadressene til den opprinnelige avsenderen og mottakerne er slettet.E-postadresser fjernes automatisk ved videresending

Ro deg ned i tilfelle Outlook-korrupsjon

Når du er utsatt for problemer i Outlook, kan du få panikk, redd for Outlook-korrupsjon. Likevel, i ærlighet, kan hastverk og bekymring ofte resultere i mange andre problemer med Outlook. Derfor, ikke få panikk, men hold deg rolig i relevante tilfeller. Dessuten, hvis du har beholdt et robust PST-fixverktøy, som DataNumen Outlook Repair, kan du ganske enkelt bruke den til å løse Outlook-problemer.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert fikse sql og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.