3 makromåter for raskt å konvertere Word-dokumentene dine til PDF Filer

I denne artikkelen vil vi fokusere på å gi deg 3 makroer som du kan bruke til å raskt konvertere Word-dokumenter til pdf filer.

I Word 2003 er det et ikon på menylinjen. Med et enkelt klikk kan brukere utløse "Lagre som"-vinduet umiddelbart og lagre dokumentet i pdf format.Lagre som PDF Ikon

Men som du legger merke til, endres oppsettet i Word 2010 mye. Og brukere må klikke på "Fil"-fanen og deretter "Lagre som"-kommandoen for å utløse "Lagre som"-vinduet. Dessuten må du manuelt velge lagringstype før du trykker på "Lagre" -knappen.Velg Lagre type

Med alle disse klikkene går det ikke raskt nok. Derfor vil vi i dette innlegget gjerne vise frem makromåten for å gjøre det.

Makro 1: Utløs "Lagre som"-vinduet raskt

  1. Først og fremst, klikk på fanen «Utvikler», og deretter på kommandoen «Visual Basic» for å åpne VBA-editoren. De to klikkene må selvfølgelig gjøres når fanen «Utvikler» allerede vises. Alternativt kan du trykke på «Alt+F11».Klikk "Utvikler" -> Klikk "Visual Basic"
  2. For det andre, klikk på "Normal" prosjekt.
  3. For det tredje, klikk "Sett inn" og velg deretter "Modul" på listemenyen.
  4. Dobbeltklikk nå på modulen for å vise redigeringsområdet.Klikk "Normal" -> Klikk "Sett inn" -> Klikk "Modul"
  5. Deretter limer du inn følgende koder:
Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub
  1. Klikk deretter "Kjør".Lim inn TriggerSaveAsWindow Macro->Klikk "Kjør"

Nå åpnes vinduet «Lagre som». Lagringstypen er allerede i PDF-format. Alt som gjenstår å gjøre er å klikke på «Lagre»-knappen. Denne makroen lar deg endre filnavnet om nødvendig.

Makro 2: Lagre Word-filer direkte til PDF

I tilfelle noen ønsker å lagre filen direkte til pdf uten å revidere filnavnet, her er makroen som trengs.

  1. Først av alt, gjenta de første 4 trinnene ovenfor.
  2. Deretter limer du inn følgende koder i stedet:
'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub
  1. På samme måte klikker du på "Kjør".

Makro 3: Konverter Word DOCX-filer til PDF-filer i batch

  1. Plasser alle docx-filer i én mappe først.
  2. Følg trinnene ovenfor for å ha redigeringsområdet åpent.
  3. Deretter limer du inn makroen nedenfor:
Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub
  1. Ikke glem å klikke på "Kjør"-knappen.

Merknader: I koder "strFolder = "C:\Users\Test\Desktop\Test Files\"”,“"C:\Users\Test\Desktop\Test Files\"" er filbanen til mappen. Husk å endre den tilsvarende.

Etter at du har kjørt denne makroen, lagres PDF-filene i samme mappe som Word-dokumentene.Effekt

Sikre filer som du kan

Det finnes forebyggende tiltak og tiltak etter katastrofer for å redde skadede filer. Hvis du fortsetter å sikkerhetskopiere filene dine regelmessig, er det bare en barnelek å få tilbake den opprinnelige filen. Sannheten er at få klarer å holde seg til sikkerhetskopieringsplanen sin, og dermed øker risikoen for å miste verdifulle data. Under slike omstendigheter er det på tide å ty til avanserte løsninger. Korrupsjonsverktøy for Word-dokumenter.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert skadet Excel xlsx fix og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.