2 måter å skrive ut listene over Outlook-oppgaver med forskjellige kategorier på forskjellige sider

Hvis du har tildelt forskjellige fargekategorier til Outlook-oppgavene dine og nå ønsker å skrive ut listene over oppgaver med forskjellige kategorier på forskjellige sider, kan du referere til denne artikkelen. Her vil vi dele deg 2 metoder for å få det.

For å klassifisere og administrere oppgavene dine godt, har du kanskje brukt fargekategorier på oppgavene dine. Nå, hvis du ønsker å skrive ut listene over oppgavene dine med forskjellige kategorier på forskjellige sider, vennligst les videre. I det følgende vil vi introdusere deg 2 måter å få det til.

Metode 1: Skriv ut oppgavelister manuelt én etter én

1. Først av alt, i Outlook, åpne "Oppgaver"-ruten.
2. Deretter åpner du en oppgavemappe.
3. Deretter trykker du på "Ctrl + E" for å aktivere "Søk"-båndet.
4. Etter det, på "Søk"-fanen, klikk på "Kategoriser" -knappen.
5. Velg en fargekategori fra rullegardinlisten.
6. Da vil bare oppgavene med den valgte kategorien stå igjen i listen.
7. Gå nå til "Fil"> "Skriv ut" for å skrive ut denne oppgavelisten.
8. Deretter skriver du på samme måte ut oppgavelistene med de andre fargekategoriene én etter én manuelt.

Metode 2: Batch-skriv ut oppgavelistene av VBA

1. Helt i begynnelsen, utløs VBA-editor i henhold til "Hvordan kjøre VBA-kode i Outlook".
2. Legg deretter til referansen til «MS Excel Object Library» som beskrevet i «Slik legger du til en objektbibliotekreferanse i VBA".
3. Deretter kopierer du følgende VBA-kode til en modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Trykk deretter på "F5"-tasten for å kjøre denne makroen med en gang.
5. Når makroen er ferdig, vil listene over oppgaver med forskjellige kategorier bli skrevet ut på forskjellige sider, som vist på følgende skjermbilde.

Få tilbake verdifulle data fra kompromittert PST-fil

Hvis du er underlagt en utilgjengelig PST-fil, er ditt neste trinn utvilsomt PST reparasjon. I dette tilfellet kan du først prøve reparasjonsverktøyet for innboks. Forutsatt at det mislykkes, kan du fortsette å prøve et annet eksternt verktøy, for eksempel DataNumen Outlook Repair. Den er i stand til å gjenopprette PST-data på rask tid.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert gjenopprette mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med