Hoe u snel dubbele ontvangers uit uw Outlook-e-mail kunt verwijderen met VBA

Als u contactgroepen toevoegt aan het veld "Aan" van de huidige e-mail, kunnen er enkele dubbele zijn. In dit artikel leert u hoe u VBA kunt gebruiken om snel dubbele ontvangers te verwijderen.

Als u bij het opstellen van een e-mail niet alleen contacten toevoegt, maar ook contactgroepen als ontvangers, kunnen er soms enkele dubbele ontvangers zijn omdat de contactgroepen standaard zijn samengevouwen. Als u in dit geval de dubbele wilt achterhalen, moet u eerst de contactgroepen uitbreiden en vervolgens de ontvangers handmatig vergelijken, wat uitgebreid is geïntroduceerd in mijn vorige artikel - "Hoe u dubbele ontvangers uit uw Outlook-e-mails kunt verwijderen​ Het is zonder enige twijfel erg vervelend. Veel gebruikers verlangen dus naar een snelle manier om dubbele ontvangers te verwijderen. In het volgende zullen we u leren om het te krijgen met Outlook VBA.

Verwijder snel dubbele ontvangers in uw Outlook-e-mail

1. Start in de eerste plaats uw Outlook-applicatie.
2. Schakel vervolgens over naar het tabblad "Ontwikkelaar" en klik op de knop "Visual Basic" of druk gewoon op de toetsen "Alt + F11".
3. Vervolgens kunt u in het venster "Microsoft Visual Basic for Applications" een lege module openen.
4. Kopieer en plak vervolgens de volgende VBA-codes in deze module.

Sub RemoveDuplicateRecipients()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact groups in "To" field
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend
 
    'Remove the duplicate recipients
    For i = objRecipients.Count To 1 Step -1
        For n = (i - 1) To 1 Step -1
            If objRecipients(i).Address = objRecipients(n).Address Then
               objRecipients(i).Delete
               Exit For
            End If
        Next
    Next
End Sub

5. Daarna kunt u het nieuwe VBA-project toevoegen in de werkbalk Snelle toegang van het berichtvenster.
6. Later moet u uw Outlook-macrobeveiligingsniveau op laag zetten.
7. Eindelijk kun je het proberen.

• Stel eerst een e-mail op zoals gewoonlijk.
• Voeg vervolgens contactgroepen en contacten toe in het veld "Aan".
• Vervolgens kunt u op de nieuwe macroknop in de werkbalk Snelle toegang klikken.
• In één keer zal Outlook automatisch de contactgroepen uitvouwen en vervolgens de dubbele ontvangers verwijderen.

Bescherm uw waardevolle Outlook-gegevens

Omdat Outlook kan crashen, zijn uw Outlook-gegevens vatbaar voor corruptie. U moet dus veel moeite doen om uw Outlook-bestand te beschermen. Allereerst moet u regelmatig een back-up van uw PST-bestand maken. Het zal vergemakkelijken corrupte PST reparatie. Bovendien kunt u beter een krachtig handig hulpmiddel voor het repareren voorbereiden, zoals DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder mdf-oplossing en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com