Hoe u het verzenden van specifieke e-mails snel kunt uitstellen tot werkuren in uw Outlook

Als u wilt voorkomen dat u bepaalde e-mails buiten werkuren verstuurt, kunt u de methode gebruiken die in dit artikel wordt getoond. Het kan Outlook automatisch laten controleren of het binnen werkuren is wanneer u specifieke e-mails verzendt en het uitstellen tot werkuren.

Soms valt het moment waarop u een e-mail opstelt en verzendt niet binnen uw werkuren. In dat geval kunt u het verzenden van deze e-mail uitstellen tot de volgende werkuren. Over het algemeen kunt u de native functie "Vertraagde bezorging" gebruiken om dergelijke e-mails te vertragen. Op die manier moet u echter elke keer de levertijd aangeven. Het is te lastig. Hierna zullen we u een stukje VBA-code delen, die automatisch kan controleren of het binnen werkuren is wanneer u een specifieke e-mail verzendt en het verzenden ervan snel uitstelt tot de werkuren.

Stel het verzenden van specifieke e-mails snel uit tot werkuren

1. Start vanaf het begin uw Outlook-programma.
2. Vervolgens kunt u in het opkomende hoofdscherm van Outlook op de toetsen "Alt + F11" drukken.
3. Vervolgens krijgt u met succes toegang tot de Outlook VBA-editor.
4. Daarna moet u het "ThisOutlookSession" -project zoeken en openen.
5. Kopieer vervolgens de volgende VBA-code naar dit projectvenster.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As MailItem
    Dim NewSendTime As String
    Dim bDelayMail As Boolean
    Dim nPrompt As Integer
 
    bDelayMail = True
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Work on specific emails only
       'You can change the conditions as per your needs
       If objMail.Recipients.Item(1).Address = "boss@datanumen.com" Then
 
          Select Case Weekday(Date, vbMonday)
                 'Delay 2 days if today is Saturday
                 Case 6
                      NewSendTime = (Date + 2) & " 09:00:00"
                 'Delay 1 days if today is Saturday
                 Case 7
                      NewSendTime = (Date + 1) & " 09:00:00"
                 Case Else
                      If DatePart("h", Now) < 9 Then
                         'Delay to 9 o'clock if now is too early
                         NewSendTime = Date & " 09:00:00"
                      ElseIf DatePart("h", Now) > 18 Then
                         Select Case Weekday(Date, vbMonday)
                                'Delay 3 days if today is Friday and now is over 6 PM
                                Case 5
                                     NewSendTime = (Date + 3) & " 09:00:00"
                                'Delay to 9 o'clock if now is before 6 PM
                                Case Else
                                     NewSendTime = (Date + 1) & " 09:00:00"
                         End Select
                      Else
                         bDelayMail = False
                      End If
            End Select
 
            If bDelayMail = True And objMail.DeferredDeliveryTime = "1/1/4501" Then
               'Ask if to delay sending this email
               nPrompt = MsgBox("Outside Working Hours:" & vbCrLf & "Do you want to delay this email until " & NewSendTime & "?", vbYesNo + vbExclamation, "Delay Email")
 
               If nPrompt = vbYes Then
                  objMail.DeferredDeliveryTime = NewSendTime
               Else
                  objMail.DeferredDeliveryTime = "1/1/4501"
               End If
           End If
       End If
    End If
End Sub

6. Later moet u een digitaal certificaat aan deze e-mail toewijzen.
7. En verander vervolgens uw Outlook-macro-instellingen om de ondertekende macro's toe te staan.
8. Vanaf nu krijgt u elke keer dat u e-mails verzendt die voldoen aan de vooraf gedefinieerde criteria, buiten de werkuren, een prompt zoals de volgende afbeelding:
9. Als u "Ja" selecteert, plant Outlook dat het wordt verzonden tot werkuren.

Red beschadigde Outlook-bestanden

Outlook heeft veel complimenten verdiend vanwege de talloze functies. Het heeft echter nog steeds een dodelijke fout. Dat is Outlook is vatbaar voor fouten en corruptie. Daarom moet u regelmatig een back-up van uw Outlook-bestanden maken. Het kan voorkomen dat u pijnlijk Outlook-gegevensverlies lijdt. Bovendien kun je maar beter een machtige reparatietool aanschaffen, zoals DataNumen Outlook Repair, welke kan reparatie Outlook problemen binnen enkele seconden.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder mdf herstel en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com