Snel de specifieke dia's van een PowerPoint Presentatie in uw Outlook-e-mail

Als u de specifieke dia's van een PowerPoint presentatie naar een aparte nieuwe presentatie en als bijlage bij een Outlook-e-mail, kunt u de manier gebruiken die in dit artikel wordt gedeeld.

In plaats van een geheel PowerPoint presentatie naar een e-mail, als u de specifieke dia's van de presentatie wilt bijvoegen, moet u in het algemeen eerst de specifieke dia's naar een nieuwe presentatie kopiëren. Het is te lastig. Daarom laten we u hier een methode zien waarmee u dit in één keer kunt realiseren.

Bevestig de specifieke dia's van een PowerPoint Presentatie in een e-mail

1. Open eerst het specifieke PowerPoint presentatie.
2. Vervolgens in de PowerPoint toepassingsvenster, druk op "Alt + F11" toetsen om toegang te krijgen tot de VBA-editor.
3. Maak vervolgens in het nieuwe venster een nieuwe module door op "Invoegen"> "Module" te klikken.
4. Kopieer en plak vervolgens de volgende VBA-code in deze module.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Daarna kunt u het huidige venster sluiten.
6. Ga later naar "Bestand"> "Opties"> "Werkbalk Snelle toegang" om de nieuwe macro toe te voegen aan Werkbalk Snelle toegang.
7. Eindelijk kunt u deze macro proberen.

• Selecteer om te beginnen de specifieke dia's die u wilt extraheren.
• Klik vervolgens op de macroknop in de werkbalk Snelle toegang.
• Meteen verschijnt er een Outlook-e-mail met een PowerPoint presentatie die is geëxtraheerd uit de bronpresentatie.

Gebruik een effectief herstelprogramma

Zoals we allemaal weten, is Outlook uitgerust met een ingebouwd reparatieprogramma - scanpst. Toch kan het eenvoudig omgaan met kleine storingen in Outlook. Als u wordt geconfronteerd met ernstige schade, heeft dit geen gevolgen. Op dat moment heb je geen andere keuze dan terug te keren naar een andere krachtige en betrouwbare reparatietool, zoals DataNumen Outlook Repair. Hiermee kunt u uw beschadigde Outlook-bestand redden.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder beschadigde mdf en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com