Snel meerdere Excel-werkmapbijlagen samenvoegen en exporteren naar één werkmap in Outlook

Als u een e-mail ontvangt die is bijgevoegd met meerdere Excel-werkmappen en u de inhoud van alle werkmappen in één werkmap wilt controleren, kunt u de weg in dit artikel gebruiken. Het exporteert meerdere Excel-werkmapbijlagen naar één werkmap.

Om alle bijlagen van een e-mail in één Excel-werkmap te bekijken, moet u deze bijlagen eerst samenvoegen en exporteren naar één werkmap. In plaats van dit handmatig te doen, kunt u de volgende methode gebruiken om dit moeiteloos te bereiken. Deze methode leert u hoe u VBA-code kunt gebruiken. Voor meer informatie over het gebruik van VBA kunt u het bericht "Hoe u VBA-code in uw Outlook uitvoert'.

Snel meerdere Excel-werkmapbijlagen samenvoegen en exporteren naar één werkmap in Outlook

Samenvoegen en exporteren van meerdere Excel-werkmapbijlagen in één werkmap

  1. Begin met het openen van de Outlook-applicatie.
  2. Open vervolgens de Outlook VBA-editor.
  3. Vervolgens moet u in het nieuwe venster "Microsoft Visual Basic for Applications" de "MS Excel Object Library" inschakelen. Raadpleeg hiervoor het artikel "Hoe voeg je een verwijzing naar een objectbibliotheek toe in VBA?'.
  4. Kopieer vervolgens de volgende VBA-code naar een project of module.
Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA-code - Meerdere Excel-werkmapbijlagen samenvoegen en exporteren in één werkmap

  1. Daarna kunt u het venster sluiten en de nieuwe macro toevoegen aan de werkbalk Snelle toegang.
  2. Pitch later op de bron-e-mail in de mailinglijst.
  3. Houd vervolgens "Ctrl" ingedrukt om de Excel-werkmapbijlagen te selecteren die u wilt exporteren.
  4. Klik vervolgens op de macroknop in de werkbalk Snelle toegang.Voer de Macro-knop uit in de werkbalk Snelle toegang
  5. Wanneer de macro is voltooid, wordt een nieuwe Excel-werkmap weergegeven. Het bevat de inhoud van de eerder geselecteerde Excel-werkmappen.Geëxporteerde Excel-werkmap

Val terug op een Mightier External Repair Tool

Wanneer Outlook corrupt raakt, zullen de meeste gebruikers geneigd zijn gebruik te maken van... inbox reparatieprogramma om het in de eerste plaats te proberen. Het zal echter niet veel helpen bij ernstige schade. Op dat moment heeft u geen andere keuze dan hulp te krijgen van een externe betrouwbare en ervaren tool, zoals DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder mdf herstel en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.