Batch verzenden Alle bestanden in een Windows-map verzenden via afzonderlijke Outlook-e-mails

Als u alle bestanden in een Windows-map via afzonderlijke Outlook-e-mails naar iemand wilt verzenden, kunt u de methode gebruiken die in dit artikel is geïntroduceerd. Het maakt gebruik van VBA-code, wat behoorlijk effectief is.

Na het lezen van mijn vorige artikel – “3 snelle methoden om alle bestanden in een lokale map bij een Outlook-e-mail te voegen”, willen sommige gebruikers alle bestanden in een lokale map via afzonderlijke e-mails verzenden. Standaard moet u e-mails maken en de bestanden één voor één bijvoegen. Het is nogal lastig. Daarom zullen we u in het volgende een effectievere manier voorstellen.

Batch Stuur alle bestanden in een Windows-map via afzonderlijke e-mails

1. Start allereerst het Outlook-programma.
2. Open vervolgens in Outlook de VBA-editor met verwijzing naar het artikel - "Hoe u VBA-code in uw Outlook uitvoert'.
3. Kopieer en plak vervolgens de volgende VBA-code in een project of module.

Sub SendAllFilesInSeparateEmails()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFile As Object
    Dim strWindowsFolder As String
    Dim objFileSystem As Object
    Dim objMail As Outlook.MailItem
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objWindowsFolder = objFileSystem.GetFolder(strWindowsFolder)
 
       'Send each file in an email
       For Each objFile In objWindowsFolder.Files
 
           'Create a new mail
           Set objMail = Outlook.Application.CreateItem(olMailItem)
           'Change the details as per your needs
           With objMail
                .Subject = Left(objFile.Name, Len(objFile.Name) - (Len(objFileSystem.GetExtensionName(objFile.Name)) + 1))
                .Attachments.Add objFile.Path
                .Recipients.Add ("someone@datanumen.com")
                .Recipients.ResolveAll
                .Send
          End With
       Next
 
       'Prompt you when completing sending
       MsgBox "All done!", vbOKOnly + vbExclamation
    End If
End Sub

4. Daarna kunt u deze macro in één keer uitvoeren. Druk gewoon op de toets "F5".
5. Vervolgens moet u de Windows-bronmap selecteren in het pop-upvenster.
6. Uiteindelijk zal Outlook alle bestanden in deze Windows-map bijvoegen om e-mails te scheiden en de e-mails naar de vooraf gedefinieerde ontvanger te sturen.
7. Als het klaar is, krijg je een bericht met de vraag "All done!".

Houd Outlook Health in de gaten

Hoewel Outlook wordt aangeprezen als de populairste e-mailclient op de markt, heeft het toch een fatale tekortkoming: de kwetsbaarheid. Met andere woorden, Outlook is vatbaar voor allerlei fouten en corruptie. Daarom is het van groot belang om de gezondheid van uw Outlook te waarborgen en deze te beschermen tegen schade. Daarnaast is het raadzaam om regelmatig een back-up van uw Outlook-bestanden te maken. Het is ook aan te raden om een ​​PST-reparatietool aan te schaffen, zoals... DataNumen Outlook Repair. Het kan reparatie Outlook probleemloos oplossen.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql-oplossing en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com