Meerdere Outlook-e-mails batchgewijs exporteren naar één Word-document via VBA

Outlook-oplossingen 29 september 2025

Als u meerdere Outlook-e-mails batchgewijs wilt exporteren naar één woorddocument, kunt u de VBA-code gebruiken die in dit artikel wordt getoond. Het kan u helpen om deze taak binnen enkele seconden te volbrengen.

Ik heb ooit geïntroduceerd hoe je een Outlook-e-mail converteert naar een Word-document in mijn vorige artikel - "2 effectieve methoden om een ​​Outlook-e-mail naar een Word-document te converteren”. Echter, zowel de 2 middelen genoemd in die post zal hulpeloos zijn in het geval dat u veel e-mails batchgewijs naar één Word-document wilt exporteren. Daarom zullen we je hier een andere manier leren. Lees nu verder om het uitgebreid te krijgen.

Batch Exporteer meerdere Outlook-e-mails naar één Word-document via VBA

Batch Exporteer meerdere Outlook-e-mails naar één Word-document

  1. Aan start met, start uw Outlook-programma.
  2. Vervolgens, na het openen van het hoofdvenster van Outlook, moet u op de toetsen "Alt + F11" drukken.
  3. Vervolgens krijgt u toegang tot de Outlook VBA-editor, waarin u een lege module moet openen.
  4. Kopieer vervolgens onderstaande VBA-code in het geopende modulevenster.
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA-code - Batchexporteer meerdere Outlook-e-mails naar één Word-document

  1. Daarna kunt u dit nieuwe VBA-project beter toevoegen aan de werkbalk Snelle toegang of het lint.
  2. Uiteindelijk kunt u het proberen.
  • Selecteer in de eerste plaats meerdere Outlook-e-mails.
  • Zoek en klik vervolgens op de nieuw toegevoegde macroknop.
  • Nadat u wordt gevraagd om "Voltooid", kunt u naar de vooraf gedefinieerde lokale map bladeren om een ​​nieuw Word-document te zoeken.
  • Open dit document, waarin u kunt zien dat alle geselecteerde e-mails zijn geëxporteerd.

Houd een Mighty Recovery Tool in de buurt

Ongeacht de vele functies, kan Outlook nog steeds niet immuun zijn voor fouten. Als u gewend bent om fouten met rust te laten, terwijl ze zich opstapelen, zal Outlook vastlopen. Op dat moment is het essentieel om terug te keren naar een krachtige en effectieve hersteltool, zoals DataNumen Outlook Repair. Het is er goed thuis in PST-oplossing. Zolang u ermee bezig bent, hoeft u zich geen zorgen meer te maken over het verlies van Outlook-gegevens.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder beschadigde mdf en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.