Batch toevoegen of verwijderen van meerdere AutoTekst-items in uw Word

In dit bericht laten we u graag zien hoe u meerdere AutoTekst-items tegelijk kunt toevoegen of verwijderen in uw Word-document.

Voor teksten die u vaak gebruikt, kunt u ze toevoegen aan de AutoTekst-galerie. Zo hoeft u de volgende keer niet al die teksten handmatig opnieuw te typen. U kunt in plaats daarvan de gewenste tekst opzoeken en erop klikken. De tekst wordt dan ingevoegd op de positie van uw cursor.

Zoals ons onderwerp suggereert, willen we u nu de methode laten zien om meerdere AutoTekst-fragmenten batchgewijs toe te voegen of te verwijderen om uw kostbare tijd te besparen.

Voeg in batch meerdere AutoTekst-vermeldingen toe

1. Eerst moet u een tabel met 2 kolommen maken. Zet de naam van het AutoTekst-item in de eerste kolom. En plaats de invoerinhoud in de tweede kolom. Hier is de demonstratie:
2. Open vervolgens de VBA-editor door op "Alt + F11" te drukken.
3. Klik vervolgens op "Normaal" project.
4. Klik vervolgens op het tabblad "Invoegen" in de menubalk en selecteer "Module".
5. Dubbelklik nu op de nieuwe module om deze te openen.
6. Plak de volgende codes:

Sub BatchAddAutoTextEntries()
  Dim objTable As Table
  Dim objEntry As Cell
  Dim objEntryRange As Range
  Dim objEntryNameRange As Range
  Dim nRowNumber As Integer
 
  Set objTable = ActiveDocument.Tables(1)
  nRowNumber = 1
  For Each objEntry In objTable.Columns(2).Cells 
    Set objEntryNameRange = objTable.Cell(nRowNumber, 1).Range
    objEntryNameRange.MoveEnd Unit:=wdCharacter, Count:=-1 
    Set objEntryRange = objEntry.Range
    objEntryRange.MoveEnd Unit:=wdCharacter, Count:=-1
    objEntryRange.Select 
    NormalTemplate.AutoTextEntries.Add Name:=objEntryNameRange.Text, _
                                             Range:=Selection.Range
    nRowNumber = nRowNumber + 1
  Next objEntry
  MsgBox "All entries in the table are added to the gallery."
End Sub

7. Klik ten slotte op "Uitvoeren" of druk op "F5".

Als het klaar is, ontvangt u een berichtvenster zoals hieronder:

U kunt de toegevoegde vermeldingen niet zien in de huidige en alle reeds geopende documenten. Om het effect te zien, moet u een nieuw document openen. Vervolgens kunt u het resultaat controleren door op het tabblad "Invoegen" op "Snelle onderdelen" te klikken. Kies vervolgens "AutoTekst" en u zult zien dat alle vermeldingen in de tabel aan de galerij zijn toegevoegd.

Batch Meerdere AutoTekst-vermeldingen verwijderen

In de volgende inhoud laten we u zien hoe u meerdere AutoTekst-fragmenten batchgewijs kunt verwijderen.

1. Maak eerst een tabel van één kolom. En plaats elke invoernaam in één cel.
2. Herhaal vervolgens stap 2 tot en met 7 hierboven. Maar vergeet niet om macro te vervangen door deze:

Sub BatchDeleteAutoTextEntries()
  Dim objTable As Table
  Dim objEntry As Cell
  Dim objEntryNameRange As Range
  Dim objEntryRange As Range
  Dim nRowNumber As Integer
 
  Set objTable = ActiveDocument.Tables(1)
  nRowNumber = 1
  For Each objEntry In objTable.Columns(1).Cells
    Set objEntryNameRange = objTable.Cell(nRowNumber, 1).Range
    objEntryNameRange.MoveEnd Unit:=wdCharacter, Count:=-1
    On Error Resume Next
    NormalTemplate.AutoTextEntries.Item(objEntryNameRange.Text).Delete
    nRowNumber = nRowNumber + 1
  Next objEntry
  MsgBox "All entries in the table are deleted from the gallery."
End Sub

Evenzo wordt het van kracht in nieuwe documenten die daarna worden geopend.

Blijf kalm wanneer gegevensverlies optreedt

Naarmate het gebruik van computers toeneemt, neemt ook het gegevensverlies elk jaar toe. Gegevensverlies kan uw carrière op het spel zetten. Het is zo'n frustrerende ervaring die je nooit meer wilt meemaken. Dan komt hier het belang van doc-oplossing. U dient altijd vooraf een reparatiegereedschap bij de hand te hebben.

Auteur Introductie:

Vera Chen is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder Excel-herstel en pdf reparatie softwareproducten. Voor meer informatie bezoek www.datanumen.com