2 Methoden om snel geselecteerde cellen in een Excel-werkblad te verzenden als een Outlook-e-mail

Soms wilt u de geselecteerde cellen in een Excel-werkblad snel invoegen in een Outlook-e-mail en deze e-mail verzenden. In dit artikel wordt deze wens besproken om u 2 methoden aan te bieden.

Mijn vorige artikel "2 snelle methoden om een ​​Excel-werkblad als een Outlook-e-mail te verzenden”Heeft je geleerd hoe je een heel Excel-werkblad als e-mail verstuurt. Soms wilt u de geselecteerde cellen in een werkblad echter alleen als e-mail verzenden. In reactie op deze vereiste zullen we u hier 2 methoden laten zien. U kunt een van beide kiezen volgens uw voorkeur.

Methode 1: kopieer geselecteerde cellen handmatig naar e-mail

1. Open om te beginnen het bron-Excel-bestand en ga naar het juiste Excel-werkblad.
2. Selecteer vervolgens de cellen die u als Outlook-e-mail wilt verzenden.
3. Druk vervolgens op de sneltoetsen "Ctrl + C" om de geselecteerde cellen te kopiëren.
4. Start daarna uw Outlook-applicatie.
5. Klik vervolgens op de knop "Nieuwe e-mail" in het lint "Home" om een ​​nieuwe Outlook-e-mail aan te maken.
6. Klik later in het nieuwe berichtvenster in de berichttekst.
7. En druk vervolgens op de toetsen "Ctrl + V" om de eerder gekopieerde geselecteerde Excel-cellen te plakken.
8. Ten slotte kunt u zoals gewoonlijk de e-mail opstellen en op de knop "Verzenden" klikken om deze te verzenden.

Methode 2: geselecteerde cellen verzenden als e-mail via VBA

1. Open vanaf het begin de Excel-bronwerkmap.
2. Druk vervolgens op de toets "Alt + F11" om toegang te krijgen tot de Excel VBA-editor.
3. Klik in het nieuwe venster op “Invoegen”> “Module” om een ​​nieuwe module in te voegen.
4. Schakel vervolgens het Microsoft Outlook-object in. Klik op 'Extra' > 'Verwijzingen'. Zoek in het pop-upvenster de 'Microsoft Outlook-objectbibliotheek' en vink deze aan.
5. Kopieer vervolgens de volgende VBA-code naar deze module.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Uiteindelijk kun je het proberen.

• Selecteer eerst de specifieke cellen zoals gewoonlijk.
• Ga dan terug naar de nieuwe macro en druk op F5 om deze te activeren.
• Meteen wordt een nieuwe Outlook-e-mail weergegeven, waarin u kunt zien dat de geselecteerde cellen in de hoofdtekst van de e-mail zijn ingevoegd, zoals in de volgende schermafbeelding:

PST-bestand is hetzelfde kwetsbaar als Excel-bestand

Zoals we weten, zijn Excel-bestanden en Word-documenten gevoelig voor corruptie. Hetzelfde geldt eigenlijk voor PST-bestanden, die alle items in uw Outlook-mailbox bevatten. Het beveiligen van uw PST-gegevens is daarom een ​​lastige klus. Een van de meest effectieve maatregelen is om regelmatig een back-up van het bestand te maken. Om direct te kunnen herstellen, is het bovendien verstandig om een ​​geavanceerd hulpmiddel bij de hand te hebben, zoals... DataNumen Outlook Repair, dat kan Outlook herstellen gegevens zonder een zweet te breken.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder reparatie mdf en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com