Snel het laatst gewijzigde bestand in een Windows-map toevoegen aan uw Outlook-e-mail

Soms wilt u snel het laatst gewijzigde bestand in een specifieke Windows-map vinden en bij een Outlook-e-mail voegen. In dit geval kunt u de methode gebruiken die in dit artikel is geïntroduceerd.

Sommige gebruikers willen dat Outlook snel het laatst gewijzigde bestand in een Windows-map vindt en dit aan een e-mail toevoegt, bijvoorbeeld het meest recent aangemaakte, gewijzigde of opgeslagen bestand. Outlook biedt deze functie echter niet standaard. Daarom laten we hieronder een stukje VBA-code zien waarmee dit eenvoudig kan worden gerealiseerd.

Voeg het laatst gewijzigde bestand in een Windows-map toe aan e-mail

1. Om te beginnen moet u uw Outlook-toepassing starten.
2. Nadat u in het hoofdvenster van Outlook bent gekomen, kunt u op de toetsen "Alt + F11" drukken.
3. Vervolgens krijgt u met succes toegang tot het Outlook VBA-editorvenster.
4. Vervolgens moet u een module zoeken en openen die niet wordt gebruikt.
5. En kopieer en plak vervolgens de volgende VBA-code in dit modulevenster.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Daarna kunt u het huidige VBA-editorvenster verlaten en doorgaan met het toevoegen van de nieuwe macro aan de werkbalk Snelle toegang of het lint van het berichtvenster.
7. Later moet u het macrobeveiligingsniveau van Outlook op laag zetten.
8. Uiteindelijk kun je het proberen.

• Maak en stel eerst een nieuwe Outlook-e-mail op zoals gewoonlijk.
• Druk vervolgens op de macroknop in de werkbalk Snelle toegang, zoals de afbeelding hieronder:
• Vervolgens moet u een Windows-bronmap selecteren en op "OK" klikken.
• Als er zo'n bestand in de geselecteerde Windows-map staat, krijg je een prompt zoals de volgende schermafbeelding:
• Als u op "Ja" klikt, wordt dit bestand meteen bijgevoegd.

Los Outlook-problemen zo snel mogelijk op

Telkens wanneer u Outlook-problemen tegenkomt, is het raadzaam deze zo snel mogelijk op te lossen. In deze situatie kun je beter een robuust Outlook-oplossing tool van tevoren, zoals DataNumen Outlook Repair​ Het is in staat om PST-fouten te herstellen en uw Outlook-gegevens effectief te redden.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder beschadigde mdf en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com