Hoe de e-mails automatisch te verplaatsen met specifieke CC-ontvangers in Outlook

Outlook-oplossingen 29 september 2025

In de praktijk hopen de meesten van jullie waarschijnlijk een Outlook-regel te maken om e-mails met specifieke CC-ontvangers automatisch te verplaatsen. Maar Outlook-regels ondersteunen het controleren van CC-ontvangers niet. Dit artikel laat je daarom zien hoe je dit met Outlook VBA kunt realiseren.

Het is duidelijk dat het voor u onmogelijk is om een ​​Outlook-regel te maken om specifieke CC-ontvangers te doorzoeken. Zoals te zien is in de volgende schermafbeelding, kunt u voor ontvangen e-mails alleen controleren of uw eigen naam in het CC-vak staat. Evenzo is er voor verzonden e-mails zelfs geen regelvoorwaarde om het CC-vakje aan te vinken.Geen voorwaarden om CC-ontvanger te zoeken

Daarom, als u Outlook wilt configureren om de e-mails met specifieke CC-ontvangers automatisch te verplaatsen, moet u andere middelen zoeken. Dan. hier leren we je hoe je dit kunt bereiken door middel van Outlook VBA.

Verplaats automatisch de verzonden e-mails met specifieke CC-ontvangers

  1. Ga eerst naar het tabblad "Ontwikkelaar" en klik op de knop "Visual Basic".
  2. Open vervolgens het project "ThisOutlookSession" en kopieer de volgende VBA-codes erin.
Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

Verplaats automatisch de verzonden e-mails met specifieke CC-ontvangers

  1. Vervolgens moet u doorgaan met het ondertekenen van deze code en de macro-instellingen zoals gewoonlijk wijzigen.
  2. Ten slotte kunt u het venster "Visual Basic" verlaten. Daarna worden de e-mails met de specifieke CC-ontvangers verplaatst naar de opgegeven e-mailmap.

Verplaats de ontvangen e-mails automatisch met specifieke CC-ontvangers

Nu de bovenstaande VBA-code bedoeld is om verzonden e-mails met specifieke CC-ontvangers te verplaatsen. Als u naar specifieke CC-ontvangers in ontvangen e-mails wilt zoeken en deze vervolgens wilt verplaatsen, moet u in plaats daarvan de volgende codes gebruiken.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Verplaats de ontvangen e-mails automatisch met specifieke CC-ontvangers

Blijf goed voorbereid op Outlook-corruptie

Hoewel Outlook rijk is aan functies, kan het nog steeds niet immuun zijn voor corruptie. U moet dus waakzaam blijven voor alle mogelijke risico's. De cruciale stap moet ongetwijfeld het maken van een consistente en up-to-date back-up voor Outlook-gegevens zijn. Verder dient u een corrupte Outlook-hersteltool in de buurt. Het is handig als zowel de back-ups als Scanpst.exe mislukken.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder reparatie SQL Server mdf-bestandsfout en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.