6 manieren om de originele e-mailbijlagen te behouden bij het beantwoorden in Outlook

Outlook-oplossingen 29 september 2025

Veel gebruikers hopen hun Outlook zo te configureren dat de originele e-mailbijlagen behouden blijven wanneer ze een e-mail beantwoorden. Dit artikel beschrijft 5 tijdelijke oplossingen en een slimme manier die VBA gebruikt om dit automatisch te realiseren.

Ik heb een groot aantal gebruikers horen klagen dat Outlook geen native-functie heeft om originele bijlagen te bewaren bij het beantwoorden van een e-mail. Daarom zullen we u hier 6 methoden delen, waarvan er één erg handig is omdat het VBA gebruikt om Outlook automatisch de originele bijlagen te laten bijvoegen bij het beantwoorden van e-mail. Lees nu verder om ze in detail te krijgen.

Bewaar de originele e-mailbijlagen bij het beantwoorden in Outlook

1. Beantwoord met de originele e-mail bijgevoegd

Hoewel Outlook geen functie biedt voor het bewaren van originele e-mailbijlagen bij het beantwoorden van een e-mail, kunnen gebruikers originele e-mailbijlagen behouden. Daarom is het een optionele oplossing voor u. U kunt naar "Bestand"> "Opties"> "E-mail"> "Antwoorden en doorsturen" gaan om de antwoordinstellingen te wijzigen. Voor meer details wordt u aangeraden om naar mijn vorige artikel te verwijzen - "5 stappen om te antwoorden met originele bijlagen in Outlook”. Maar als je nog steeds hoopt alleen de originele bijlagen te behouden, ga dan verder om de andere middelen te leren.

2. Handmatig bijlagen slepen en neerzetten

  1. Aan starDubbelklik op een dergelijke bron-e-mail om deze in een eigen venster te openen.
  2. Klik vervolgens op de knop "Beantwoorden", waardoor de antwoord-e-mail verschijnt.
  3. Vervolgens moet u beide berichtvensters verkleinen totdat u ze in hetzelfde scherm kunt zien.
  4. Selecteer daarna alle bijlagen in de originele e-mail.
  5. Sleep ze ten slotte naar de regel "Bijgevoegd" in de antwoord-e-mail.Handmatig bijlagen slepen en neerzetten

3. Handmatig bijlagen kopiëren en plakken

  1. Selecteer in de eerste plaats alle bijlagen na het openen van de bron-e-mail.
  2. Klik vervolgens op de knop "Kopiëren" onder het tabblad "Bijlagen".Kopieer alle bijlagen
  3. Klik daarna op de knop "Beantwoorden" onder het tabblad "Bericht" om een ​​antwoordmail te openen.
  4. Klik uiteindelijk in de antwoordende e-mail op de regel "Bijgevoegd" en druk op "Ctrl + V" om de eerder gekopieerde bijlagen te plakken.

4. E-mail doorsturen en ontvanger invullen

  1. Selecteer eerst zo'n e-mail en klik vervolgens op de knop "Doorsturen" in het lint.
  2. In het nieuwe pop-upvenster Bericht worden de originele bijlagen bewaard. Nu moet u het veld "Aan" invullen voor de afzender van de originele e-mail.
  3. Optioneel kunt u het onderwerp naar wens wijzigen.

5. Verzend deze e-mail opnieuw en wijzig de ontvangers

  1. Open om te beginnen de bron-e-mail.
  2. Klik vervolgens op de knop "Acties" in de groep "Verplaatsen".
  3. Kies vervolgens "Dit bericht opnieuw verzenden" in de vervolgkeuzelijst.
  4. Misschien krijgt u een melding dat u niet de oorspronkelijke afzender bent. Negeer het gewoon en druk op "Ja".
  5. In de volgende nieuwe e-mail moet u het veld "Aan" wijzigen in de afzender van de oorspronkelijke e-mail.
  6. Vergeet ook niet om het verzenden via e-mailaccount naar uw eigen account te wijzigen.

6. Automatisch originele bijlagen toevoegen via VBA

Alle hierboven genoemde benaderingen zijn, om eerlijk te zijn, tijdelijke oplossingen. Als u hoopt dat Outlook bij het beantwoorden automatisch originele bijlagen kan bewaren, kunt u op deze manier gebruikmaken.

  1. Druk in het hoofdvenster van Outlook op de toetsen "Alt + F11".
  2. Kopieer vervolgens in het venster "Microsoft Visual Basic for Applications" de onderstaande VBA-code naar het project "ThisOutlookSession".
Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

VBA-code - Bewaar de originele e-mailbijlagen bij het beantwoorden

  1. Onderteken deze macro later en wijzig uw Outlook-macro-instellingen om de ondertekende macro's toe te staan.
  2. Daarna restart uw Outlook-applicatie om dit VBA-project te activeren.
  3. Vanaf nu elke keer dat u op de knop "Beantwoorden" klikt. De antwoordende e-mail wordt meteen weergegeven met de originele bijlagen.

Gebruik een uitstekend reparatieprogramma

Outlook heeft het beter gedaan dan andere e-mailclients vanwege de talloze functies. Maar het is nog steeds vatbaar voor corruptie. Daarom moet u meer aandacht besteden aan de gezondheid ervan. Over het algemeen kunt u bij kleine problemen gewoon teruggaan naar het ingebouwde fix-hulpprogramma. Niettemin, als u ernstige problemen ondervindt, kunt u beter teruggaan naar een veel bekwamer hulpmiddel, zoals DataNumen Outlook Repair. Het kan Outlook repareren bestand in een oogwenk.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql-oplossing en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.