Hoe u de mapstructuur van uw Outlook-bestand naar Excel exporteert

Als u de mappenstructuur van uw Outlook-gegevensbestand snel naar een Excel-werkmap wilt exporteren, kunt u de methode gebruiken die in dit artikel wordt geïntroduceerd.

Om bepaalde redenen, zoals het loggen van huidige Outlook-mappen en submappen, hopen veel gebruikers de mapstructuur van een Outlook-bestand te exporteren naar een extern bestand, zoals een Excel-werkmap. In het volgende zullen we u een stukje VBA-code delen, waarmee u dit in een handomdraai kunt bereiken.

Exporteer de mappenstructuur van uw Outlook-bestand naar Excel

1. Begin met het openen van de Outlook-applicatie.
2. Druk vervolgens in het hoofdvenster van Outlook op de toetsen "Alt + F11".
3. Vervolgens komt u in de Outlook VBA-editor, waarin u een ongebruikte module zou moeten openen.
4. Vervolgens kunt u de volgende VBA-code naar deze module kopiëren.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Daarna moet u ervoor zorgen dat Outlook macro's heeft ingeschakeld.
6. Uiteindelijk kun je een kans maken:

• Druk in het huidige macrovenster op de F5-toets.
• Nadat de macro is voltooid, krijgt u een waarschuwing met de vraag "Voltooid".
• Later kunt u naar de vooraf gedefinieerde lokale map gaan om een ​​nieuw Excel-bestand te zoeken. Open het en het ziet eruit als de volgende schermafbeelding:

Negeer nooit Outlook-fouten

Ondanks de vele mogelijkheden, is Outlook hetzelfde vatbaar voor fouten en corruptie als andere e-mailclients. Daarom moet u belang hechten aan alle fouten in uw Outlook. Negeer ze alstublieft niet. Anders kunnen opeenstapelende fouten uiteindelijk leiden tot corruptie van Outlook. Als u met knoestige fouten wordt geconfronteerd, wordt aangeraden om een ​​krachtig hulpmiddel te gebruiken, zoals DataNumen Outlook Repair, welke kan reparatie Outlook fouten binnen enkele seconden.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql herstel en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com