2 snelle manieren om secties uit uw Word-document te extraheren

In dit artikel bieden we u 2 snelle en gemakkelijke manieren om secties uit uw Word-document te extraheren naar een andere of meerdere.

Het komt vrij vaak voor om inhoud van het ene document naar het andere te extraheren. En in ons vorige artikel hebben we besproken hoe u pagina's uit een document kunt extraheren. Voor gedetailleerde informatie kunt u dit artikel raadplegen: 2 snelle manieren om afzonderlijke pagina's uit uw Word-document te extraheren

Vandaag laten we u zien hoe u per sectie kunt extraheren.    

Methode 1: Extract huidige sectie naar een nieuw document

1. Plaats allereerst de cursor in het gewenste gedeelte.
2. Druk vervolgens op "Alt + F11" om de VBA-editor in Word op te roepen.
3. Klik vervolgens in de linkerkolom op "Normaal".
4. En klik op de menubalk op "Invoegen".
5. Kies vervolgens "Module" in dat vervolgkeuzemenu.
6. Dubbelklik om de nieuwe module te openen en plak de volgende codes daar:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Klik vervolgens op "Uitvoeren" op de menubalk of druk op "F5".
8. Dan zal er het "Bladeren" venster verschijnen. Kies een plaats om het nieuwe document op te slaan en klik op "OK".
9. En voer in het vak “Bestandsnaam” de naam voor het nieuwe bestand in en klik op “OK”.

Nu heb je de sectie uitgepakt naar een nieuw document.

Methode 2: extraheer elke sectie in het document naar individuele nieuwelingen

Op deze manier kunt u alle secties in een document batchgewijs verwerken. Natuurlijk hebben we ook een macro nodig.

1. Open om te beginnen het doeldocument.
2. Volg daarna de stappen in methode 1 om een ​​macro te installeren en uit te voeren.
3. Vervang deze keer alleen die macro door deze:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Kies toch een opslagpad in het venster "Bladeren" en klik op "OK".

Herstel irritante woordfouten

Het is normaal dat u tijdens het gebruik enkele Word-fouten tegenkomt. Vervelend misschien, we moeten er de tijd voor nemen woord terughalen zo spoedig mogelijk. Omdat hoe langer we het uitstellen, des te ernstiger het gegevensverlies kan zijn. Daarom wordt aanbevolen om van tevoren een reparatieprogramma aan te schaffen.

Auteur Introductie:

Vera Chen is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder beschadigde xls en pdf reparatie softwareproducten. Voor meer informatie bezoek www.datanumen.com