2 snelle manieren om afzonderlijke pagina's uit uw Word-document te extraheren

In dit artikel delen we twee snelle manieren om afzonderlijke pagina's uit je Word-document te halen.

Soms kan in een Word-document elke pagina vrij onafhankelijke inhoud bevatten, zoals een tabel. En u zult waarschijnlijk verschillende tafels naar verschillende mensen moeten sturen. Vervolgens moet u elke tabel die elke pagina is, als een afzonderlijk bestand opslaan.

Het eerste idee dat bij ons opkomt, zou het klassieke kopiëren en plakken moeten zijn. Toch kan alles wat met selectie te maken heeft, soms vervelend zijn, want door te slepen en te selecteren kan er gemakkelijk een einde komen zonder dat er een selectie is gemaakt. Om deze reden raden we u 2 snelle methoden aan met macro om de klus te klaren.

Methode 1: de huidige pagina extraheren en opslaan als een nieuw document

1. Plaats allereerst uw cursor op de pagina die u wilt extraheren.
2. Klik op het tabblad "Ontwikkelaar" en klik vervolgens op "Visual Basic" om de VBA-editor op te roepen. Als de "Developer" niet is geactiveerd, drukt u gewoon op "Alt + F11".
3. Ten tweede, ga naar “Normaal” project door erop te klikken.
4. Klik vervolgens op het tabblad "Invoegen" en kies "Module".
5. Dubbelklik op de nieuwe module om het bewerkingsgebied te openen.
6. Plak daar dan de volgende codes:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Klik ten slotte op de knop "Uitvoeren".

Nu zullen er 2 invoervakken zijn. Voer het pad in waar u het nieuwe document wilt opslaan in het eerste invoervak. En voer de nieuwe documentnaam in op de tweede.

Methode 2: extraheer elke pagina en sla deze op als een nieuw document

Met de volgende macro kunt u elke afzonderlijke pagina van een document extraheren.

1. Druk eerst op "Ctrl + Home" om naar het begin van uw document te gaan.
2. Volg daarna dezelfde stappen in methode 1 om een ​​macro te installeren en uit te voeren.
3. Vervang deze keer de macro door deze:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Behandel woordkwesties

Er zijn en zullen altijd diverse problemen met Word zijn. Het gaat erom te leren hoe je ze op de juiste manier oplost. De meest aanbevolen manier is natuurlijk om een ​​geavanceerd Word-programma aan te schaffen. Woordherstel gereedschap. U moet elke minuut benutten om uw gegevens te herstellen voordat het te laat is.

Auteur Introductie:

Vera Chen is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder corrupte xlsx en pdf reparatie softwareproducten. Voor meer informatie bezoek www.datanumen.com