Outlook Email တစ်ခုမှ Excel Worksheet သို့ လျှင်မြန်စွာ ထုတ်ယူနည်း

မဲပေးခလုတ်များပါသည့် အီးမေးလ်တစ်စောင် ပေးပို့ထားပါက၊ လက်ခံသူများက သင့်ထံ ၎င်းတို့၏ အကြောင်းပြန်မှုများ ပေးပို့ပြီးနောက်၊ မဲပေးမှုစာရင်းအင်းများကို ရေတွက်ပြီး Excel worksheet သို့ ထုတ်ယူလိုပေမည်။ ထို့ကြောင့် ဤပို့စ်တွင် ၎င်းကို မည်သို့လျင်မြန်စွာ အောင်မြင်ရမည်ကို သင်ကြားပေးပါမည်။

Outlook သည် အလွန်အစွမ်းထက်သောကြောင့် ၎င်းသည် "မဲပေးခြင်း" အင်္ဂါရပ်ကိုပင် ပေးဆောင်ပါသည်။ ငါ့ရဲ့အရင်ဆောင်းပါး"Voting အတွက် MS Outlook ကို ကျွမ်းကျင်စွာ အသုံးပြုခြင်း။” က ၎င်းကို မည်သို့ထိရောက်စွာအသုံးပြုရမည်ကို သင်ကြားပေးခဲ့သည်။ ထို့အပြင်၊ မဲပေးပြီးနောက်၊ စာရင်းအင်းများကို ပရင့်ထုတ်လိုခြင်းကဲ့သို့သော အချို့သောအကြောင်းပြချက်များကြောင့် မဲပေးမှုစာရင်းအင်းများကို Excel worksheet သို့ တင်ပို့နိုင်သည်။ သို့သော် Outlook သည် ၎င်းကို default အနေဖြင့် မပံ့ပိုးပါ။ ထို့ကြောင့်၊ အောက်ပါတို့တွင်၊ ၎င်းကို ဖော့ကဲ့သို့ မည်သို့လုပ်ဆောင်ရမည်ကို သင်ကြားပေးပါမည်။

အီးမေးလ်တစ်ခုတွင် မဲပေးမှုစာရင်းအင်းများကို Excel Worksheet တစ်ခုသို့ ထုတ်ယူပါ။

1. အစပိုင်းတွင် သင်၏ Outlook အက်ပ်ကို စတင်ပါ။
2. ထို့နောက် ပင်မ Outlook ဝင်းဒိုးရှိ “Alt + F11” ခလုတ်များကို နှိပ်သင့်သည်။
3. နောက်တစ်ခုကတော့ “Microsoft Visual Basic for Applications” ဝင်းဒိုးမှာ “Microsoft Excel Object Library” ကို enable လုပ်သင့်ပါတယ်။ “Tools” > “Reference” ကို နှိပ်ပါ။ ပြီးရင် popup dialog box မှာ “Microsoft Excel Object Library” ရှေ့က check box ကို အမှန်ခြစ်ပြီး နောက်ဆုံးမှာ “OK” ကိုနှိပ်ပါ။
4. ထို့နောက်တွင်၊ သင်သည် မော်ဂျူးအသစ်တစ်ခုကို ထည့်သွင်းနိုင်သည် သို့မဟုတ် အသုံးမပြုရသေးသောတစ်ခုကို ဖွင့်နိုင်သည်။
5. ထို့နောက်တွင်၊ အောက်ပါ VBA ကုဒ်များကို ဤ module ထဲသို့ ကူးယူပြီး ကူးထည့်ပါ။

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. ထို့နောက်တွင်၊ အဆင်ပြေစွာဝင်ရောက်နိုင်ရန်၊ Quick Access Toolbar တွင် မက်ခရိုအသစ်ကို ပိုမိုကောင်းမွန်စွာထည့်နိုင်သည်။
6. နောက်ဆုံးတွင်၊ သင်ကြိုးစားနိုင်သည်။

• ပထမဦးစွာ၊ မဲပေးခြင်းခလုတ်များပါရှိသော အရင်းအမြစ်အီးမေးလ်ကို ရွေးချယ်ပါ။
• ထို့နောက် Quick Access Toolbar ရှိ မက်ခရိုခလုတ်ကို နှိပ်ပါ။
• ဤ macro လည်ပတ်မှုအပြီးတွင်၊ Excel workbook အသစ်ကိုသင်တွေ့မြင်ရမည့်ကြိုတင်သတ်မှတ်ထားသော local folder သို့သင်ရှာဖွေနိုင်သည်။
• ဤ Excel အလုပ်စာအုပ်ကိုဖွင့်ပါ။ ယခုအောက်ပါပုံတွင်ပြထားသည့်မဲစာရင်းဇယားကိုမြင်ရပါမည်-

Outlook Errors များကို မည်သူမျှ စေ့စေ့စပ်စပ် ရှောင်နိုင်မည်မဟုတ်ပေ။

Outlook သည် စွမ်းရည်အမျိုးမျိုးဖြင့် ထောက်ပံ့ပေးထားသော်လည်း Outlook error များကို ရှောင်ရှားရန် ကျွန်ုပ်တို့ကို ကူညီပေးနိုင်သည့် အင်္ဂါရပ်မရှိပါ။ အကြောင်းရင်းအမျိုးမျိုးတို့သည် Outlook အမှားများကို ဖြစ်စေနိုင်သည်။ ဥပမာအားဖြင့်၊ သင်သည် Outlook ကို မကြာခဏ မမှန်မကန် ထွက်သွားပါက၊ သင်သည် ခံစားရနိုင်ခြေ ရှိပါသည်။ PST အကျင့်ပျက်ခြစားမှု. ထိုသို့သော အခြေအနေမျိုးတွင်၊ သင်၏ PST ဖိုင်ကို ကယ်တင်ရန် အစွမ်းထက်သော ကိရိယာအချို့ကို ကိုင်ဆောင်ရန်မှတပါး ရွေးချယ်စရာ မရှိတော့ပါ။ DataNumen Outlook Repair. ၎င်း၏ ပြန်လည်ရယူမှုနှုန်း မြင့်မားမှုကြောင့် ၎င်းသည် ချီးကျူးမှုများစွာ ရရှိခဲ့သည်။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ အကျင့်ပျက် mdf နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com