တိကျသော Slides များကို လျင်မြန်စွာ ပူးတွဲနည်း PowerPoint သင်၏ Outlook အီးမေးလ်သို့တင်ပြခြင်း။

အကယ်၍ သင်သည် သီးခြားဆလိုက်များကို ထုတ်ယူလိုပါက PowerPoint တင်ဆက်မှုအသစ်တွင် သီးခြားတင်ပြချက်အသစ်တစ်ခုသို့ ၎င်းကို Outlook အီးမေးလ်တစ်ခုသို့ ပူးတွဲပါ၊ ဤဆောင်းပါးတွင်မျှဝေသည့်နည်းလမ်းကို သင်အသုံးပြုနိုင်ပါသည်။

တစ်ခုလုံးကို တွဲမယ့်အစား PowerPoint တင်ဆက်မှု၏ တိကျသောဆလိုက်များကို အီးမေးလ်ဖြင့် ပူးတွဲတင်ပြလိုပါက၊ ယေဘုယျအားဖြင့်၊ သင်တင်ပြချက်အသစ်တစ်ခုသို့ ဦးစွာ ကူးယူတင်ပြရန် လိုအပ်ပါသည်။ ဒုက္ခရောက်လွန်းတယ်။ ထို့ကြောင့် ဤနေရာတွင် တစ်ကြိမ်တည်း သဘောပေါက်နိုင်သည့် နည်းလမ်းကို ဖော်ပြပါမည်။

တိကျသော Slides များကို ပူးတွဲပါ။ PowerPoint အီးမေးလ်တစ်ခုသို့တင်ပြခြင်း။

1. ပထမဦးစွာ သီးခြားကိုဖွင့်ပါ။ PowerPoint တင်ပြချက်။
2. ထို့နောက်၌ PowerPoint အပလီကေးရှင်းဝင်းဒိုး၊ VBA တည်းဖြတ်မှုကို ဝင်ရောက်ရန် “Alt + F11” ခလုတ်များကို နှိပ်ပါ။
3. ထို့နောက်၊ ဝင်းဒိုးအသစ်တွင်၊ "Insert" > "Module" ကိုနှိပ်ခြင်းဖြင့် module အသစ်တစ်ခုကိုဖန်တီးပါ။
4. ထို့နောက်၊ အောက်ပါ VBA ကုဒ်ကို ဤ module ထဲသို့ ကူးယူပြီး ကူးထည့်ပါ။

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. ၎င်းနောက်၊ သင်သည်လက်ရှိဝင်းဒိုးကိုပိတ်နိုင်သည်။
6. နောက်ပိုင်းတွင်၊ Quick Access Toolbar သို့ မက်ခရိုအသစ်ထည့်ရန် “File” > “Options” > “Quick Access Toolbar” သို့ သွားပါ။
7. နောက်ဆုံးအနေနဲ့ ဒီ macro ကို စမ်းကြည့်နိုင်ပါတယ်။

• အစပြုရန်အတွက်၊ သင်ထုတ်ယူလိုသော သီးခြားဆလိုက်များကို ရွေးချယ်ပါ။
• ထို့နောက် Quick Access Toolbar ရှိ မက်ခရိုခလုတ်ကို နှိပ်ပါ။
• တစ်ချိန်တည်းတွင်၊ Outlook အီးမေးလ်တစ်ခုပေါ်လာလိမ့်မည်။ PowerPoint အရင်းအမြစ်တင်ပြချက်မှ ထုတ်နုတ်ထားသော တင်ပြချက်။

ထိရောက်သော Recovery Tool ကိုအသုံးပြုပါ။

ကျွန်ုပ်တို့အားလုံးသိကြသည့်အတိုင်း Outlook သည် built-in ပြုပြင်ခြင်းဆိုင်ရာအသုံးဝင်မှုတစ်ခုပါရှိသည်။ scanpst. သို့တိုင်၊ ၎င်းသည် Outlook တွင် သေးငယ်သောချို့ယွင်းချက်များကို ရိုးရှင်းစွာ ရင်ဆိုင်နိုင်သည်။ သင်ကြုံတွေ့နေရသောအရာသည် ပြင်းထန်သော ပျက်စီးမှုဖြစ်ပါက ၎င်းသည် အကျိုးသက်ရောက်မှုရှိမည်မဟုတ်ပါ။ ထိုအချိန်တွင်၊ ကဲ့သို့သော အစွမ်းထက်ပြီး ယုံကြည်စိတ်ချရသော ပြုပြင်ရေးကိရိယာကို ထပ်တလဲလဲလုပ်ရန် ရွေးချယ်စရာမရှိတော့ပါ။ DataNumen Outlook Repair. ၎င်းနှင့်အတူ၊ သင်သည် သင်၏ ပျက်စီးနေသော Outlook ဖိုင်ကို ကယ်တင်နိုင်မည်ဖြစ်သည်။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ mdf ပျက်စီးနေသည်။ နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com