သင်၏ Outlook တွင် အခြေအနေအလိုက် လုပ်ဆောင်စရာအားလုံးကို အမြန်ရေတွက်နည်း

လုပ်ဆောင်စရာများတွင် အခြေအနေငါးခုရှိနိုင်သည် - "မစတင်ရသေးပါ"၊ "လုပ်ဆောင်ဆဲ"၊ "ပြီးစီးပါပြီ"၊ "အခြားသူတစ်ဦးကို စောင့်ဆိုင်းနေသည်" နှင့် "ရွှေ့ဆိုင်းထားသည်"။ လုပ်ဆောင်စရာအားလုံးကို အခြေအနေအလိုက် လျင်မြန်စွာ ရေတွက်လိုပါက ဤဆောင်းပါးတွင် မိတ်ဆက်ပေးထားသည့် နည်းလမ်းကို အသုံးပြုနိုင်ပါသည်။

Outlook က အသုံးပြုသူတွေကို task တွေ ဒါမှမဟုတ် flagged items တွေကို status သတ်မှတ်ပေးဖို့ ပံ့ပိုးပေးပါတယ်။ status ငါးခုရှိပါတယ် - "Not Started"၊ "In Process"၊ "Completed"၊ "Waiting someone for waiting" နဲ့ "Deferred" တို့ဖြစ်ပါတယ်။ Outlook မှာ task အများကြီးရှိပြီး status အမျိုးမျိုးမှာ ရှိနေနိုင်ပါတယ်။ အခု task အားလုံးကို status အလိုက် ရေတွက်ချင်ရင် အောက်ပါနည်းလမ်းကို အသုံးပြုနိုင်ပါတယ်။

အခြေအနေအရ လုပ်ဆောင်စရာအားလုံးကို အမြန်ရေတွက်ပါ။

1. ပထမဦးစွာ၊ "" ကိုရည်ညွှန်းခြင်းဖြင့် Outlook VBA အယ်ဒီတာကိုဖွင့်ပါ။သင်၏ Outlook တွင် VBA ကုဒ်ကိုမည်သို့ဖွင့်မည်နည်း။"။
2. ထို့နောက် VBA editor တွင် “MS Excel Object Library” နှင့် “MS Scripting Runtime” တို့ကို “enable” လုပ်ပါ။VBA မှာ Object Library Reference ထည့်နည်း"။
3. ထို့နောက်၊ အသုံးမပြုသော module တစ်ခုသို့ အောက်ပါကုဒ်ကို ကူးယူပါ။

Dim objDictionary As New Scripting.Dictionary

Sub CountTasksByStatus()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varStatuses As Variant
    Dim varTaskCounts As Variant
    Dim i As Integer
    Dim nLastRow As Integer
 
    'Count by Dictionary
    Set objDictionary = CreateObject("Scripting.Dictionary")
  
    'Process All Outlook data files
    For Each objStore In Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olTaskItem Then
               Call ProcessTaskFolders(objFolder)
            End If
        Next
    Next
 
    'Export the counts to an Excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
        .Cells(1, 1) = "Status"
        .Cells(1, 1).Font.Bold = True
        .Cells(1, 2) = "Task Count"
        .Cells(1, 2).Font.Bold = True
    End With
 
    varStatuses = objDictionary.Keys
    varTaskCounts = objDictionary.Items
 
    For i = LBound(varStatuses) To UBound(varStatuses)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
            .Cells(nLastRow, 1) = varStatuses(i)
            .Cells(nLastRow, 2) = varTaskCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

Sub ProcessTaskFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objTask As Outlook.TaskItem
    Dim strStatus As String
    Dim objSubfolder As Outlook.Folder
 
    'Count tasks by status
    For Each objTask In objCurFolder.Items
        Select Case objTask.Status
               Case olTaskNotStarted
                    strStatus = "Not Started"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
               Case olTaskInProgress
                    strStatus = "In Progress"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
               Case olTaskComplete
                    strStatus = "Completed"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
               Case olTaskWaiting
                    strStatus = "Waiting on someone else"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
               Case olTaskDeferred
                    strStatus = "Deferred"
 
                    If objDictionary.Exists(strStatus) Then
                       objDictionary(strStatus) = objDictionary(strStatus) + 1
                    Else
                       objDictionary.Add strStatus, 1
                    End If
         End Select
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessTaskFolders(objSubfolder)
       Next
    End If
End Sub

4. ထို့နောက် ပထမလုပ်ရိုးလုပ်စဉ်ခွဲသို့ နှိပ်ပြီး “F5” ခလုတ်ကို နှိပ်ပါ။
5. Macro ပြီးသွားသောအခါတွင်၊ အောက်ဖော်ပြပါ screenshot ကဲ့သို့ Excel worksheet အသစ်တစ်ခုပေါ်လာလိမ့်မည်။ ၎င်းတွင် မတူညီသောအခြေအနေများတွင် လုပ်ဆောင်စရာအရေအတွက်များပါရှိသည်။

Outlook အနီးတဝိုက်ရှိ Pitfalls များကို သတိထားပါ။

ဗိုင်းရပ်စ်များ၊ လူသားအမှားများ၊ ဆော့ဖ်ဝဲချို့ယွင်းမှုများအပြင် ဟာ့ဒ်ဝဲချို့ယွင်းမှုများ စသည်တို့အပါအဝင် Outlook ဝန်းကျင်တွင် အန္တရာယ်များစွာရှိနေပါသည်။ ထို့ကြောင့် သင်၏တန်ဖိုးရှိသော Outlook ဒေတာကို မဆုံးရှုံးလိုပါက အချိန်တိုင်းသတိထားပါ။ ရိုးရိုးရှင်းရှင်းပြောရလျှင် သင်သည် အမည်မသိ ပူးတွဲပါဖိုင်များ သို့မဟုတ် အီးမေးလ်များတွင် သံသယဖြစ်ဖွယ်လင့်ခ်များကို ဘယ်တော့မှ ဒေါင်းလုဒ်မလုပ်သင့်ပါ။ ထို့အပြင် ဖြစ်နိုင်ပါက၊ ကဲ့သို့သော မှတ်သားဖွယ်ကောင်းသော Outlook fix utility ကိုထားရှိရန် အကြံပြုလိုပါသည်။ DataNumen Outlook Repairအနီးတစ်ဝိုက်တွင် လုံးဝအားကိုးမည့်အစား၊ inbox ပြုပြင်ရေးကိရိယာ.

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ sql ပြန်လည်ရယူပါ။ နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com