Outlook ရှိ တိကျသော CC လက်ခံသူများဖြင့် အီးမေးလ်များကို အလိုအလျောက်ရွှေ့နည်း

တကယ်တော့၊ CC လက်ခံသူတွေနဲ့ အီးမေးလ်တွေကို အလိုအလျောက် ရွှေ့ဖို့ Outlook rule တစ်ခု ဖန်တီးဖို့ မျှော်လင့်နိုင်ပါတယ်။ ဒါပေမယ့် Outlook rule က CC လက်ခံသူတွေကို စစ်ဆေးတာကို မပံ့ပိုးပါဘူး။ ဒါကြောင့် ဒီဆောင်းပါးက Outlook VBA နဲ့ ဘယ်လိုလုပ်ရမလဲဆိုတာ သင်ပေးပါလိမ့်မယ်။

အတိအကျ CC လက်ခံသူများကို ရှာဖွေရန် Outlook စည်းမျဉ်းကို သင်ဖန်တီးရန် မဖြစ်နိုင်သည်မှာ ထင်ရှားပါသည်။ အောက်ဖော်ပြပါ ဖန်သားပြင်ဓာတ်ပုံတွင် ပြထားသည့်အတိုင်း လက်ခံရရှိထားသော အီးမေးလ်များအတွက်၊ သင့်ကိုယ်ပိုင်အမည်သည် CC အကွက်တွင် ရှိ၊ မရှိ စစ်ဆေးနိုင်ပါသည်။ အလားတူပင်၊ ပေးပို့ထားသောအီးမေးလ်များအတွက် CC box ကိုစစ်ဆေးရန် စည်းကမ်းသတ်မှတ်ချက်မရှိပါ။

ထို့ကြောင့်၊ သင်သည် သတ်မှတ်ထားသော CC လက်ခံသူများဖြင့် အီးမေးလ်များကို အလိုအလျောက် ရွှေ့ရန် Outlook ကို configure လုပ်လိုပါက၊ သင်သည် အခြားနည်းလမ်းကို ရှာရပါမည်။ ပြီးတော့။ ဤနေရာတွင် Outlook VBA ဖြင့် ၎င်းကိုအောင်မြင်အောင်ပြုလုပ်နည်းကို သင်ပေးပါမည်။

သတ်မှတ်ထားသော CC လက်ခံသူများဖြင့် ပေးပို့ထားသော အီးမေးလ်များကို အလိုအလျောက် ရွှေ့ပါ။

1. ပထမဦးစွာ "Developer" tab သို့လှည့်ပြီး "Visual Basic" ခလုတ်ကိုနှိပ်ပါ။
2. ထို့နောက် “ThisOutlookSession” ပရောဂျက်ကိုဖွင့်ပြီး အောက်ပါ VBA ကုဒ်များကို ၎င်းထဲသို့ ကူးယူပါ။

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. ထို့နောက်တွင် သင်သည် ဤကုဒ်ကို လက်မှတ်ထိုးပြီး ပုံမှန်အတိုင်း မက်ခရိုဆက်တင်များကို ပြောင်းလဲရန် ဆက်လက်လုပ်ဆောင်သင့်သည်။
4. နောက်ဆုံးအနေဖြင့်၊ သင်သည် "Visual Basic" window မှထွက်နိုင်သည်။ ယင်းနောက်၊ သတ်မှတ်ထားသော CC လက်ခံရရှိသူများပါရှိသည့် အီးမေးလ်များကို သတ်မှတ်ထားသော မေးလ်ဖိုင်တွဲသို့ ရွှေ့သွားပါမည်။

တိကျသော CC လက်ခံသူများဖြင့် လက်ခံရရှိထားသောအီးမေးလ်များကို အလိုအလျောက်ရွှေ့ပါ။

ယခု အထက်ဖော်ပြပါ VBA ကုဒ်သည် သတ်မှတ်ထားသော CC လက်ခံသူများဖြင့် ပေးပို့ထားသော အီးမေးလ်များကို ရွှေ့ရန် ရည်ရွယ်ထားသောကြောင့် လက်ခံရရှိထားသောအီးမေးလ်များတွင် CC လက်ခံသူများကို ရှာဖွေပြီး ၎င်းကို ရွှေ့လိုပါက၊ ၎င်းအစား အောက်ပါကုဒ်များကို အသုံးပြုသင့်ပါသည်။

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Outlook Corruption အတွက် ကောင်းမွန်စွာ ပြင်ဆင်ထားပါ။

Outlook သည် အင်္ဂါရပ်ကြွယ်ဝသော်လည်း အကျင့်ပျက်ခြစားမှုကို ခံနိုင်ရည်မရှိသေးပါ။ ဒါကြောင့် ဖြစ်နိုင်ချေရှိတဲ့ အန္တရာယ်အားလုံးကို သတိထားသင့်ပါတယ်။ အရေးကြီးသောအဆင့်သည် Outlook ဒေတာအတွက် တသမတ်တည်းနှင့် နောက်ဆုံးပေါ် အရန်ကူးယူခြင်းကို ပြုလုပ်ရမည်မှာ သေချာပါသည်။ ထိုမျှသာမက စောင့်ရှောက်သင့်သည် ပျက်စီးနေသော Outlook ပြန်လည်ရယူရေးကိရိယာ အနီးတစ်ဝိုက်တွင်။ Backup နှင့် Scanpst.exe နှစ်ခုလုံး မအောင်မြင်ပါက ၎င်းသည် အဆင်ပြေလာပါလိမ့်မည်။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ ပြုပြင် SQL Server mdf ဖိုင်အမှား နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com