အမည်မသိ ပေးပို့သူများထံမှ ဝင်လာသော Outlook အီးမေးလ်များတွင် ဟိုက်ပါလင့်ခ်များကို အလိုအလျောက်ပိတ်နည်း

အန္တရာယ်ရှိသောလင့်ခ်များကိုပိတ်ဆို့ရန်၊ အမည်မသိပေးပို့သူများထံမှဝင်လာသောအီးမေးလ်များအတွင်းရှိ ဟိုက်ပါလင့်ခ်များကို အလိုအလျောက်ပိတ်ရန် သင်၏ Outlook ကို ပိုမိုကောင်းမွန်စွာသတ်မှတ်ပေးစေလိုပါသည်။ ဤဆောင်းပါးသည် သင့်အား ဖော့ကဲ့သို့ရရန် ကူညီပေးနိုင်သည့် VBA ကုဒ်အပိုင်းအစကို ဖော်ပြပါမည်။

အီးမေးလ်မှ ပေါက်ဖွားလာသော ဗိုင်းရပ်စ်များသည် ၎င်းတို့၏ Outlook ဖိုင်ကို တိုက်ခိုက်ခဲ့ကြောင်း သုံးစွဲသူအများအပြားက စောဒကတက်ခဲ့ကြသည်။ များသောအားဖြင့်၊ ၎င်းတို့သည် အမည်မသိ ပေးပို့သူများထံမှ ထိုအီးမေးလ်များကို အလွယ်တကူ ယုံကြည်သောကြောင့် ဖြစ်သည်။ ထို့ကြောင့် ၎င်းတို့သည် မေးလ်များရှိ ဟိုက်ပါလင့်ခ်များကို ဒေါင်းလုဒ်လုပ်ခြင်း သို့မဟုတ် နှိပ်ပါ။ အခုနောက်ပိုင်းမှာ နည်းလမ်းတစ်ခုကို မျှဝေပေးပါမယ်။ Outlook သည် အမည်မသိ ပေးပို့သူများထံမှ ဝင်လာသော အီးမေးလ်များ၏ ဟိုက်ပါလင့်ခ်များကို အလိုအလျောက် ပိတ်နိုင်စေပါသည်။ သင့်တွင်ထိုကဲ့သို့သောလိုအပ်ချက်များရှိပါကအသေးစိတ်အချက်အလက်များကိုရရန်ဆက်လက်ဖတ်ရှုပါ။

အမည်မသိ ပေးပို့သူများထံမှ ဝင်လာသော အီးမေးလ်များတွင် ဟိုက်ပါလင့်ခ်များကို အလိုအလျောက် ပိတ်ပါ။

1. အစပြုရန်အတွက် Outlook တွင် “Alt + F11” ဖြင့် VBA editor သို့သွားပါ။
2. ထို့နောက် မျက်နှာပြင်အသစ်တွင်၊ ပို့စ်တွင်ပါရှိသည့်အတိုင်း “MS VBScript Regular Expressions” object ကိုထည့်ပါ။VBA မှာ Object Library Reference ထည့်နည်း"။
3. ထို့နောက် အောက်ပါကုဒ်ကို “ThisOutlookSession” ပရောဂျက်ထဲသို့ ကူးထည့်ပါ။

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. ထို့နောက် Outlook ကို restart လုပ်ခြင်းဖြင့် သို့မဟုတ် “Application_Startup” subroutine ရှိ “F5” key ခလုတ်ကို နှိပ်ခြင်းဖြင့် ဤ macro ကို activate လုပ်ပါ။
5. ထိုအချိန်မှစ၍ ပုံမှန်အဆက်အသွယ်ဖိုင်တွဲတွင် သိမ်းဆည်းထားခြင်းမရှိသော ပေးပို့သူထံမှ ဝင်လာသည့် အီးမေးလ်သည် Inbox ထဲသို့ ရောက်ရှိသည့်အခါတိုင်း၊ Outlook သည် ၎င်းရှိ ဟိုက်ပါလင့်ခ်များကို အလိုအလျောက်ပိတ်မည်ဖြစ်သည်။

Outlook ကာကွယ်မှုတွင် လိုအပ်သော ကိစ္စရပ်များစွာ

Outlook သည် ပျက်စီးရန် အလားအလာရှိသောကြောင့် Outlook ဖိုင်ကို ကာကွယ်ရန် အလွန်ခက်ခဲသည်။ ဤတွင် ကျွန်ုပ်တို့သည် Outlook ဒေတာကာကွယ်မှုအတွင်း မရှိမဖြစ်ဆောင်ထားရမည့်အရာများစွာကို ဖော်ပြပါမည်။ ပထမဦးစွာ၊ သင်သည်သင်၏ Outlook ဒေတာကိုပုံမှန်အရန်ကူးရန်လိုအပ်သည်။ ထို့အပြင်၊ အန္တရာယ်ရှိသော ပူးတွဲပါဖိုင်များ သို့မဟုတ် ဟိုက်ပါလင့်ခ်များကဲ့သို့ ဖြစ်နိုင်ချေရှိသော အန္တရာယ်အားလုံးကို သတိပြုရန် သင့်အတွက် အရေးကြီးပါသည်။ နောက်ဆုံးအနေဖြင့်၊ သင်သည် အစွမ်းထက်သော Outlook fix tool ကို ကြိုတင်ပြင်ဆင်ထားသင့်သည်။ DataNumen Outlook Repair. လိုအပ်တဲ့အခါ သေချာပေါက် အဆင်ပြေမှာပါ။ PST ပြုပြင်ခြင်း။ ဖိုင်သော်လည်းကောင်း inbox ပြုပြင်ရေးကိရိယာသည် ပျက်ကွက်မှုကို သက်သေပြသည်။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ ပျက်စီးနေသော mdf နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com