မတူညီသောစာမျက်နှာများတွင် မတူညီသောအမျိုးအစားများဖြင့် Outlook Tasks များ၏စာရင်းများကို ပရင့်ထုတ်ရန် နည်းလမ်း 2 ခု

သင့် Outlook လုပ်ငန်းဆောင်တာများတွင် အမျိုးမျိုးသော အရောင်အမျိုးအစားများကို သတ်မှတ်ပြီး ယခု မတူညီသော စာမျက်နှာများတွင် မတူညီသော အမျိုးအစားများဖြင့် အလုပ်များစာရင်းများကို print ထုတ်လိုပါက၊ ဤဆောင်းပါးကို ကိုးကားနိုင်ပါသည်။ ဤနေရာတွင် ရယူရန် နည်းလမ်း ၂ ခုကို မျှဝေပေးပါမည်။

သင့်လုပ်ငန်းတာဝန်များကို အမျိုးအစားခွဲခြားပြီး ကောင်းမွန်စွာစီမံခန့်ခွဲနိုင်ရန်၊ သင့်လုပ်ငန်းတာဝန်များတွင် အရောင်အမျိုးအစားများကို အသုံးချနိုင်ပြီဖြစ်နိုင်သည်။ ယခု၊ သင်သည် မတူညီသော စာမျက်နှာများတွင် မတူညီသော အမျိုးအစားများဖြင့် သင့်အလုပ်များစာရင်းများကို print ထုတ်လိုပါက ကျေးဇူးပြု၍ ဆက်လက်ဖတ်ရှုပါ။ အောက်ဖော်ပြပါတွင်၊ ရယူရန် နည်းလမ်း ၂ ခုကို မိတ်ဆက်ပေးပါမည်။

နည်းလမ်း 1- လုပ်ဆောင်စရာစာရင်းများကို တစ်ခုပြီးတစ်ခု လက်ဖြင့် ပရင့်ထုတ်ပါ။

1. ပထမဦးစွာ Outlook တွင် "Tasks" အကန့်ကိုဝင်ရောက်ပါ။
2. ထို့နောက် Task folder ကိုဖွင့်ပါ။
3. ထို့နောက် “Search” ribbon ကို အသက်သွင်းရန် “Ctrl+E” ကိုနှိပ်ပါ။
4. ထို့နောက် "Search" tab တွင် "Categorize" ခလုတ်ကိုနှိပ်ပါ။
5. drop down list မှ အရောင်အမျိုးအစားတစ်ခုကို ရွေးပါ။
6. ထို့နောက် ရွေးချယ်ထားသော အမျိုးအစားပါရှိသော အလုပ်များကိုသာ စာရင်းထဲတွင် ချန်ထားခဲ့ပါမည်။
7. ယခု ဤလုပ်ဆောင်စရာစာရင်းကို ပရင့်ထုတ်ရန် “File” > “Print” သို့ သွားပါ။
8. ထို့နောက်တွင်၊ ထိုနည်းအတိုင်းပင်၊ အခြားအရောင်အမျိုးအစားများနှင့်အတူ အလုပ်များစာရင်းများကို တစ်ဦးပြီးတစ်ယောက် ကိုယ်တိုင်ရိုက်ထုတ်ပါ။

နည်းလမ်း 2- VBA ဖြင့် Task Lists ကို Batch Print လုပ်ပါ။

1. အစပိုင်းတွင်၊ "နှင့်အညီ VBA အယ်ဒီတာကို အစပျိုးပါ။သင်၏ Outlook တွင် VBA ကုဒ်ကိုမည်သို့ဖွင့်မည်နည်း။"။
2. ထို့နောက် “MS Excel Object Library” ကို ရည်ညွှန်းချက် “အတိုင်း” ထည့်ပါ။VBA မှာ Object Library Reference ထည့်နည်း"။
3. ထို့နောက်၊ အောက်ပါ VBA ကုဒ်ကို မော်ဂျူးတစ်ခုသို့ ကူးယူပါ။

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. ထို့နောက် ဤ macro ကိုချက်ချင်းလုပ်ဆောင်ရန် "F5" ခလုတ်ကိုနှိပ်ပါ။
5. မက်ခရို ပြီးသောအခါ၊ အမျိုးအစားကွဲပြားသော အလုပ်များစာရင်းများကို အောက်ဖော်ပြပါ ဖန်သားပြင်ဓာတ်ပုံတွင် ပြထားသည့်အတိုင်း မတူညီသော စာမျက်နှာများတွင် ပုံနှိပ်ပါမည်။

ပျက်စီးနေသော PST ဖိုင်မှ အဖိုးတန်ဒေတာကို ပြန်လည်ရယူပါ။

အကယ်၍ သင်သည် လက်လှမ်းမမီသော PST ဖိုင်ကို ကြုံတွေ့ရပါက၊ သင်၏ နောက်အဆင့်သည် သံသယဖြစ်ဖွယ်မရှိပါ။ PST ပြုပြင်ခြင်း။. ဤကိစ္စတွင်၊ သင်သည် ပထမဦးစွာ ဝင်စာပုံးပြုပြင်ရေးကိရိယာကို စမ်းသုံးနိုင်သည်။ မအောင်မြင်ပါက၊ ကဲ့သို့သော အခြားပြင်ပကိရိယာကို စမ်းသုံးကြည့်နိုင်ပါသည်။ DataNumen Outlook Repair. ၎င်းသည် PST ဒေတာကို အချိန်တိုအတွင်း ပြန်လည်ရယူနိုင်သည်။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ mdf ကိုပြန်လည်ရယူပါ။ နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com