Kā katru dienu uzzināt jaunu cenu piedāvājumu, pievienojot savam vārdam funkciju “Dienas citāts”

Šodienas ierakstā mēs vēlamies paskaidrot, kā pievienot funkciju “Dienas citāts” savā Word programmā, lai katru dienu apgūtu jaunu citātu.

Funkcija “Dienas citāts” katru reizi, kad startējat programmu Word, parāda vienu atšķirīgu citātu. Pirms iegrimstat milzīgā darbā, veltiet dažas sekundes, lai izlasītu gudru citātu. Tas jums nāks par labu.

Tāpēc sekojiet mūsu norādījumiem, lai tagad pievienotu šādu funkciju savam Vārdam.

Ievietojiet citātus Excel failā

1. Vispirms atveriet programmu Excel un pārdēvējiet jaunu lapu kā “Citāti”.
2. Nākamais ievads “Numurs” šūnā A1, “Citāti” šūnā B1 un “Laiki” šūnā C1.
3. Pēc tam aizpildiet A sleju ar sērijas numuriem.
4. Pievienojiet vienu citātu katrā B slejas šūnā.
5. C slejā ievadiet numuru “0”.
6. Visbeidzot, nosauciet Excel failu kā “Dienas citāts”. Un saglabājiet to mapē. Mūsu gadījumā pēc faila saglabāšanas tā pilnā adrese izskatās šādi:

C:\Users\Public\Documents\Sample\Quote of the Day.xlsx

Attiecīgi jums vajadzētu atcerēties savējo.

Jūs varat noklikšķināt šeit lai lejupielādētu faila paraugu.

Ievietojiet moduli VBA projektā

1. Vispirms aktivizējiet VBA redaktoru programmā Word, nospiežot “Alt + F11”.
2. Kreisajā panelī “Project” noklikšķiniet uz “Normal”.
3. Pēc tam izvēlņu joslā noklikšķiniet uz cilnes “Ievietot”.
4. Un nolaižamajā izvēlnē izvēlieties “Modulis”.
5. Nākamais veiciet dubultklikšķi, lai atvērtu jauno moduli.
6. Tagad tur ielīmējiet šādus kodus:

Sub AutoExec()
  Dim objExcel As Excel.Application
  Dim objWorkbook As Excel.Workbook
  Dim objWorksheet As Excel.Worksheet
  Dim nRowIndex As Integer
  Dim nMinValue As Integer
  Dim nMinRowIndex As Integer
 
  Set objExcel = CreateObject("Excel.Application")
  Set objWorkbook = objExcel.Workbooks.Open("C:\Users\Public\Documents\Sample\Quote of the Day.xlsx")
  Set objWorksheet = objWorkbook.Sheets("Quotes")
 
  ' Initialization
  nMinValue = 0
  nMinRowIndex = -1
 
  For nRowIndex = 2 To objWorksheet.UsedRange.Rows.Count
    If (nMinRowIndex = -1) Then
      nMinValue = objWorksheet.Cells(nRowIndex, 3).Value
      nMinRowIndex = nRowIndex
    Else
      If (objWorksheet.Cells(nRowIndex, 3).Value < nMinValue) Then
        nMinValue = objWorksheet.Cells(nRowIndex, 3).Value
        nMinRowIndex = nRowIndex
      End If
    End If
  Next nRowIndex
 
  frmQuoteOfTheDay.txtQuoteOfTheDay.text = objWorksheet.Cells(nMinRowIndex, 2).Value
  frmQuoteOfTheDay.Show Modal
 
  objWorksheet.Cells(nMinRowIndex, 3).Value = objWorksheet.Cells(nMinRowIndex, 3).Value + 1
 
  objWorkbook.Close SaveChanges:=True
  ' Close Excel using Quit method on the Application object.
  objExcel.Application.Quit
  '  Release the object variable.
  Set objExcel = Nothing
End Sub

7. Noklikšķiniet uz pogas Saglabāt.

Piezīmes:

Šajā koda rindiņā:

Set objWorkbook = objExcel.Workbooks.Open("C:\Users\Public\Documents\Sample\Quote of the Day.xlsx")

Atcerieties ceļa adresi aizstāt ar faktisko.

Ievietojiet lietotāja veidlapu

Tālāk mēs izveidosim lietotāja veidlapu, lai parādītu citātu.

1. Tomēr VBA redaktorā vēlreiz noklikšķiniet uz cilnes “Ievietot”.
2. Tikai šoreiz jūs izvēlaties “UserForm”.
3. Tad jums būs lietotāja veidlapa. Noklikšķiniet uz formas rokturiem, lai mainītu tā izmēru.
4. Pēc tam nospiediet “F4”, lai atvērtu logu “Properties”. Tas parādīsies ekrāna kreisajā apakšējā stūrī.
5. Nosauciet veidlapu kā “frmQuoteOfTheDay” un iestatiet tās parakstu kā “Dienas citāts”. Turklāt pareizi iestatiet fontu un fona krāsu. Un izvēlies “Nepatiesa” priekš “ShowModal”.
6. Pēc tam izvēlnes joslā noklikšķiniet uz komandas “Toolbox”, lai parādītu lodziņu.
7. Izmantojiet vadīklas, lai izveidotu tekstlodziņu, iezīmi un komandu pogu. Sakārtojiet tos šādā secībā:
8. Pēc tam jums vajadzētu iestatīt šo vadīklu rekvizītus.

• Vispirms noklikšķiniet uz etiķetes. Iestatiet parakstu tekstu kā “Dienas citāts”. Pielietojiet pareizu fonta lielumu un iestatiet fonu kā caurspīdīgu.
• Otrkārt, noklikšķiniet uz tekstlodziņa. Nosauciet to kā “txtQuoteOfTheDay”.
• Treškārt, noklikšķiniet uz komandas pogas. Nosauciet to kā “btnClose” un iestatiet parakstu kā “Aizvērt”. Pēc tam veiciet dubultklikšķi uz pogas “Aizvērt”, lai atvērtu kodēšanas apgabalu. Ievadiet šādus kodus:

Private Sub btnClose_Click()
  Unload Me
End Sub

9. Visbeidzot, saglabājiet kodus.

Katru reizi, startējot programmu Word, jūs redzēsiet lietotāja veidlapu, piemēram, šādu:

Labojiet vārdu problēmas

Ir neizbēgami saskarties ar vienu vai otru problēmu programmā Word, kas var izraisīt dokumenta bojājumus. Vissvarīgākais ir ātri un pareizi risināt katru krīzi. Tomēr tam būs nepieciešams profesionāls rīks. atgūt docx.

Autora ievads:

Vera Čena ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp bojāts Excel un pdf programmatūras produktu labošana. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar