Kā eksportēt Outlook faila mapju struktūru programmā Excel

Ja vēlaties ātri eksportēt Outlook datu faila mapju struktūru uz Excel darbgrāmatu, varat izmantot šajā rakstā ievadīto metodi.

Dažu iemeslu dēļ, piemēram, reģistrējot pašreizējās Outlook mapes un apakšmapes, daudzi lietotāji cer eksportēt Outlook faila mapju struktūru uz ārēju failu, piemēram, Excel darbgrāmatu. Turpmāk mēs jums dalīsimies ar VBA koda gabalu, kas var palīdzēt jums to ātri sasniegt.

Eksportējiet Outlook faila mapju struktūru programmā Excel

1. Lai sāktu, palaidiet savu Outlook lietojumprogrammu.
2. Pēc tam galvenajā Outlook logā nospiediet taustiņu pogas “Alt + F11”.
3. Pēc tam jūs nokļūsit Outlook VBA redaktorā, kurā jums vajadzētu atvērt neizmantotu moduli.
4. Pēc tam šajā modulī varat kopēt šādu VBA kodu.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Pēc tam jums jāpārliecinās, vai programma Outlook ir iespējojusi makro.
6. Galu galā jūs varat fotografēt:

• Pašreizējā makro logā nospiediet taustiņa F5 taustiņu.
• Kad makro būs pabeigts, jūs saņemsit brīdinājumu ar aicinājumu pabeigt.
• Vēlāk varat doties uz iepriekš noteiktu vietējo mapi, lai atrastu jaunu Excel failu. Atveriet to, un tas izskatīsies kā šāds ekrānuzņēmums:

Nekad neignorējiet nevienu Outlook kļūdu

Neskatoties uz daudzajām iespējām, programma Outlook ir tikpat uzņēmīga pret kļūdām un korupciju kā citi e-pasta klienti. Tādēļ jums jāpiešķir nozīme visām jūsu Outlook kļūdām. Lūdzu, neignorējiet tos. Pretējā gadījumā kļūdu uzkrāšanās var novest pie Outlook korupcijas. Ja saskaras ar mezglainām kļūdām, tiek ieteikts izmantot spēcīgu rīku, piemēram, DataNumen Outlook Repair, kas var labot Outlook kļūdas dažu sekunžu laikā.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sql atgūšana un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar