Kā automātiski eksportēt informāciju par ienākošajiem e-pastiem Excel failā, izmantojot Outlook VBA

Daudzi lietotāji cer, ka Outlook var automātiski eksportēt ienākošo e-pasta primāro informāciju uz Excel failu. Šajā rakstā tiks aplūkota šī prasība un ieviesta ātra metode, izmantojot Outlook VBA.

Dažreiz dažu iemeslu dēļ, piemēram, pasta statistikas dēļ, jums bieži var būt nepieciešams eksportēt e-pasta ziņojumus uz Excel failu. Parasti esošajiem saņemtajiem e-pasta ziņojumiem varat vienkārši izmantot funkciju “Importēt un eksportēt”, lai vienā piegājienā tos eksportētu programmā Excel. Tomēr, iespējams, jūs pat vēlaties, lai programma Outlook varētu automātiski eksportēt ienākošos e-pastus programmā Excel, tiklīdz tie nonāk jūsu pastkastē. Bez šaubām, programmā Outlook nav šādas vietējās funkcijas. Tādēļ jums ir jāizmanto citas pieejas, piemēram, trešās puses pievienojumprogramma vai Outlook VBA. Šeit mēs iemācīsim, kā to automātiski izveidot, izmantojot Outlook VBA. Lasiet tālāk, lai iegūtu darbības un atbilstošos kodus.

Automātiski eksportējiet informāciju par ienākošajiem e-pastiem Excel failā

1. Pirmkārt, jums vajadzētu izveidot Excel failu.

• Atveriet jaunu Excel failu.
• Pēc tam jums jāievada “Nē”. šūnā A1, “Sūtītāja vārds” šūnā B1, “Sūtītāja e-pasta adrese” šūnā C1 un “E-pasta tēma” šūnā D1 un “Saņemšanas laiks” šūnā E1, piemēram, tālāk redzamajā attēlā.
• Visbeidzot saglabājiet to vēlamajā vārdā un vēlamajā mapē.

2. Pēc tam jums vajadzētu palaist programmu Outlook.
3. Pēc tam nospiediet taustiņu "Alt + F11", kas novirzīs jūs uz VBA redaktoru.
4. Pēc tam uznirstošajā logā veiciet dubultklikšķi uz “ThisOutlookSession” kreisajā pusē.
5. Pēc tam projekta logā “ThisOutlookSession” tajā ir jākopē un jāielīmē šādi VBA kodi.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Vēlāk jums vajadzētu parakstīt šo kodu.
7. Pēc tam reztart Outlook, lai aktivizētu jauno VBA projektu.
8. Galu galā no šī brīža visi ienākošie e-pasta ziņojumi tiks automātiski eksportēti uz iepriekš iestatīto Excel failu, tiklīdz tie nonāks mapē Iesūtne. Excel fails izskatīsies šādi:

Novērsiet sāpīgu PST datu korupciju

Programma Outlook ir izpelnījusies daudz atzinību, pateicoties tās dažādajām funkcijām. Tomēr tas nenozīmē, ka tas ir drošs. Tas joprojām var tikt apdraudēts jebkurā laikā. Piemēram, ja jūs bieži aizverat programmu Outlook nepareizi, ļoti iespējams, ka jūsu PST dati tiks apdraudēti. Šajā gadījumā, ja vēlaties remonts PST datiem, jums ir jāizmanto pieredzējis rīks, piemēram, DataNumen Outlook Repair.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp atgūt mdf un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar