3 ātrie veidi, kā izdzēst tukšās rindas un kolonnas jūsu Word tabulā

Šajā ierakstā mēs jums izskaidrosim 3 ātrus veidus, kā izdzēst tukšas rindas un kolonnas Word tabulā.

Tabulas ir būtiskas dokumentam, jo ​​īpaši dažādu veidu datu glabāšanai. Dažreiz garš galds var pārsniegt lapu un pārsniegt vairākas. Tāpēc, kad galds kļūst garš un sarežģīts, varat veikt pasākumus, lai to vienkāršotu. Piemēram, jūs varat izdzēst nevajadzīgas tukšas rindas un kolonnas.

Tālāk ir norādītas 3 metodes, kuras varat izmantot.

1. metode: manuāli izdzēsiet tukšās rindas un kolonnas

1. Pirmkārt, tukšā vietā atlasiet rindu vai kolonnu.
2. Pēc tam ar peles labo pogu noklikšķiniet, lai atvērtu konteksta izvēlni. Izvēlnē attiecīgi atlasiet “Dzēst rindas” vai “Dzēst kolonnas”.

Diemžēl jūs nevarat atlasīt vairākas secīgas rindas vai kolonnas un izdzēst tās šādā veidā. Šim pieprasījumam varat atsaukties uz mūsu iepriekšējo rakstu: 5 ātras metodes, kā sērijveidā izdzēst vairākas rindas vai kolonnas Word tabulā

2. metode. Sērijā izdzēsiet visas tabulas tukšās rindas un kolonnas

1. metodei ir ierobežojums. Tāpēc mēs piedāvāsim jums iespēju tabulas rindu un kolonnu sērijveida noņemšanai, izmantojot VBA kodus.

1. Lai sāktu, novietojiet kursoru mērķa tabulā.
2. Otrkārt, aktivizējiet VBA redaktoru, nospiežot “Alt + F11”.
3. Redaktorā vispirms noklikšķiniet uz “Normāls” projekts.
4. Pēc tam izvēlnes joslā noklikšķiniet uz cilnes “Ievietot”.
5. Nolaižamajā izvēlnē izvēlieties “Modulis”.
6. Veiciet dubultklikšķi uz moduļa, lai to atvērtu, un ielīmējiet tur šādus kodus:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Visbeidzot, izvēlnes joslā noklikšķiniet uz pogas “Palaist” vai nospiediet “F5”.

Pēc dažām sekundēm visas tabulas tukšās rindas un kolonnas tiks noņemtas.

3. metode. Sērijā izdzēsiet visas tukšās rindas un kolonnas visās dokumenta tabulās

1. Vispirms atkārtojiet 2. metodes darbības, lai instalētu un palaistu makro.
2. Tikai šoreiz aizstājiet šo makro ar šādu:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Atgūt salauzto dokumentu

Mūsdienās ir vairāk nekā tikai veids, kā atgūt zaudētos datus. Piemēram, dublējumu izmantošana vienmēr ir jūsu galvenā prioritāte. Ja tas neapmierina jūsu vajadzību atgūt jaunāko informāciju, varat izmēģināt doc remonts rīks.

Autora ievads:

Vera Čena ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp xlsx remonts un pdf programmatūras produktu labošana. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar