2 ātrie veidi, kā iegūt sadaļas no jūsu Word dokumenta

Šajā rakstā mēs jums piedāvāsim 2 ātrus un vienkāršus veidus, kā iegūt sadaļas no jūsu Word dokumenta citā vai vairākos.

Satura izvilkšana no viena dokumenta citā notiek diezgan bieži. Mūsu iepriekšējā rakstā mēs esam apsprieduši, kā iegūt lapas no dokumenta. Lai iegūtu detalizētu informāciju, skatiet šo rakstu: 2 ātri veidi, kā iegūt atsevišķas lapas no jūsu Word dokumenta

Šodien mēs jums parādīsim, kā iegūt pa sadaļām.    

1. metode: izvilkt pašreizējo sadaļu jaunam dokumentam

1. Vispirms novietojiet kursoru mērķa sadaļā.
2. Pēc tam nospiediet taustiņu “Alt + F11”, lai Word izsauktu VBA redaktoru.
3. Pēc tam kreisajā kolonnā noklikšķiniet uz “Normal”.
4. Izvēlņu joslā noklikšķiniet uz “Ievietot”.
5. Pēc tam nolaižamajā izvēlnē izvēlieties “Modulis”.
6. Veiciet dubultklikšķi, lai atvērtu jauno moduli, un ielīmējiet tur šādus kodus:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Pēc tam izvēlņu joslā noklikšķiniet uz “Palaist” vai nospiediet “F5”.
8. Tad parādīsies logs “Pārlūkot”. Izvēlieties vietu jaunā dokumenta glabāšanai un noklikšķiniet uz “OK”.
9. Lodziņā “File Name” ievadiet jaunā faila nosaukumu un noklikšķiniet uz “OK”.

Tagad jūs esat izvilkis sadaļu uz jaunu dokumentu.

2. metode: izvilkiet katru dokumenta sadaļu atsevišķām jaunām personām

Tas var palīdzēt jums sērijveidā apstrādāt visas dokumenta sadaļas. Protams, mums būs nepieciešams arī makro.

1. Lai sāktu, atveriet mērķa dokumentu.
2. Pēc tam izpildiet 1. metodes darbības, lai instalētu un palaistu makro.
3. Tikai šoreiz aizstājiet šo makro ar šo:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Tomēr logā “Pārlūkot” izvēlieties krātuves ceļu un noklikšķiniet uz “Labi”.

Labot kairinošas vārdu kļūdas

Lietojot to, parasti sastopas ar dažām Word kļūdām. Kaitinoši tas varētu būt, mums ir jāvelta laiks atgūt vārdu tik drīz cik vien iespējams. Jo ilgāk mēs to aizkavējam, jo ​​smagāks var būt datu zudums. Tāpēc ir ieteicams savlaicīgi iegūt remonta utilītu.

Autora ievads:

Vera Čena ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sabojāts xls un pdf programmatūras produktu labošana. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar