Come rimuovere rapidamente i destinatari duplicati dall'e-mail di Outlook con VBA

Se aggiungi gruppi di contatti al campo "A" dell'e-mail corrente, potrebbero essercene alcuni duplicati. Questo articolo ti insegnerà come utilizzare VBA per rimuovere rapidamente i destinatari duplicati.

Quando componi un'e-mail, se non solo aggiungi contatti ma anche gruppi di contatti come destinatari, a volte potrebbero esserci alcuni destinatari duplicati poiché i gruppi di contatti sono compressi per impostazione predefinita. In questo caso, se vuoi scoprire quelli duplicati, devi prima espandere i gruppi di contatti e poi confrontare i destinatari manualmente, cosa che è stata introdotta in modo elaborato nel mio precedente articolo– “Come rimuovere i destinatari duplicati dalle e-mail di Outlook”. Senza dubbio, è molto noioso. Pertanto, molti utenti desiderano un modo rapido per rimuovere i destinatari duplicati. Di seguito, ti insegneremo a ottenerlo con Outlook VBA.

Rimuovi rapidamente i destinatari duplicati nell'e-mail di Outlook

1. In primo luogo, avvia la tua applicazione Outlook.
2. Quindi passare alla scheda "Sviluppatore" e fare clic sul pulsante "Visual Basic" o semplicemente premere i tasti "Alt + F11".
3. Avanti nella finestra "Microsoft Visual Basic for Applications", puoi aprire un modulo vuoto.
4. Successivamente, copia e incolla i seguenti codici VBA in questo modulo.

Sub RemoveDuplicateRecipients()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact groups in "To" field
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend
 
    'Remove the duplicate recipients
    For i = objRecipients.Count To 1 Step -1
        For n = (i - 1) To 1 Step -1
            If objRecipients(i).Address = objRecipients(n).Address Then
               objRecipients(i).Delete
               Exit For
            End If
        Next
    Next
End Sub

5. Successivamente, puoi aggiungere il nuovo progetto VBA nella barra degli strumenti di accesso rapido della finestra del messaggio.
6. Successivamente è necessario impostare il livello di sicurezza delle macro di Outlook su basso.
7. Finalmente puoi provare.

• Innanzitutto, componi un'e-mail come al solito.
• Quindi aggiungi gruppi di contatti e contatti nel campo "A".
• Successivamente puoi fare clic sul nuovo pulsante macro nella barra di accesso rapido.
• Immediatamente, Outlook espanderà automaticamente i gruppi di contatti e quindi rimuoverà i destinatari duplicati.

Proteggi i tuoi preziosi dati di Outlook

Poiché Outlook è soggetto a arresti anomali, i dati di Outlook sono soggetti a corruzione. Quindi, devi fare molti sforzi per proteggere il tuo file di Outlook. Prima di tutto, è necessario eseguire regolarmente il backup del file PST. Faciliterà PST corrotto riparazione. Inoltre, faresti meglio a preparare un potente strumento di correzione a portata di mano, come ad esempio DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui correzione del mdf e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com