Come esportare rapidamente i dettagli di tutti i membri in un gruppo di contatti di Outlook in Excel

Condividi ora:

Per impostazione predefinita, puoi vedere solo i nomi dei membri e gli indirizzi email in un gruppo di contatti. Se desideri ottenere gli altri dati dei membri, puoi utilizzare la modalità presentata in questo articolo.

Quando fai doppio clic su un gruppo di contatti per aprirlo, nella sua finestra puoi vedere solo i nomi e gli indirizzi email dei membri del gruppo. Non sei in grado di ottenere altri dettagli dei membri, come azienda, titolo di lavoro, numero di telefono o indirizzo commerciale, ecc. In generale, per ottenere questi dettagli, devi trovare manualmente i contatti corrispondenti ai membri nella tua cartella Contatti. È troppo fastidioso. Qui ti mostreremo un pezzo di codice VBA, che può esportare rapidamente questi dettagli in una cartella di lavoro di Excel.

Esporta rapidamente i dettagli di tutti i membri in un gruppo di contatti di Outlook in Excel

Esporta i dettagli di tutti i membri in un gruppo di contatti in Excel

  1. Per iniziare, avvia l'applicazione Outlook.
  2. Quindi dovresti premere le scorciatoie da tastiera "Alt + F11" nella finestra principale di Outlook.
  3. Successivamente nella nuova finestra "Microsoft Visual Basic for Applications", è necessario aprire un modulo non in uso o inserire direttamente un nuovo modulo.
  4. Successivamente, copia e incolla il seguente codice VBA in questo modulo.
Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

Codice VBA: esporta i dettagli di tutti i membri in un gruppo di contatti di Outlook nella cartella di lavoro di Excel

  1. Successivamente, per un comodo controllo, puoi aggiungere il nuovo progetto VBA alla barra degli strumenti di accesso rapido o al nastro.
  2. Successivamente imposta il livello di sicurezza delle macro di Outlook su basso.
  3. Alla fine, puoi provare.
  • Innanzitutto, seleziona un gruppo di contatti.
  • Quindi premere il pulsante macro nella barra degli strumenti di accesso rapido o nella barra multifunzione.Eseguire la nuova macro
  • Immediatamente, la macro verrà eseguita.
  • Al termine, riceverai un messaggio di "Completato!"
  • Successivamente, puoi andare alla cartella locale di destinazione predefinita, in cui puoi trovare un nuovo file Excel.
  • Aprilo, vedrai i dettagli di contatto dei membri del gruppo come il seguente screenshot:Dettagli membro esportati

Non farti prendere dal panico di fronte ai problemi di Outlook

Nessuno è disposto ad accettare eventuali problemi di Outlook, indipendentemente dal messaggio di errore popup o Outlook corrotto file di dati. Pertanto, gli utenti tenderanno a farsi prendere dal panico quando incontrano problemi con Outlook. Se vuoi mantenere la calma in quel caso, dovresti avere due necessità in mano. Uno è l'attuale backup dei dati di Outlook. L'altro è un potente software di correzione di Outlook, come DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui ripristino sql e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com

Condividi ora:

I commenti sono chiusi.