Come allegare rapidamente l'ultimo file modificato in una cartella di Windows all'e-mail di Outlook

A volte, potresti voler trovare rapidamente e allegare l'ultimo file modificato in una specifica cartella di Windows a un'e-mail di Outlook. In questo caso, puoi utilizzare il metodo introdotto in questo articolo.

Alcuni utenti desiderano che Outlook individui e alleghi rapidamente a un'e-mail l'ultimo file modificato in una cartella di Windows, ad esempio il file creato, modificato o salvato più di recente. Tuttavia, Outlook non offre una funzionalità nativa di questo tipo. Pertanto, di seguito, mostreremo un frammento di codice VBA che consente di realizzare questa operazione con facilità.

Allega l'ultimo file modificato in una cartella di Windows all'e-mail

1. All'inizio, dovresti avviare la tua applicazione Outlook.
2. Quindi, dopo essere entrato nella finestra principale di Outlook, puoi premere i pulsanti "Alt + F11".
3. Successivamente accederai alla finestra dell'editor VBA di Outlook con successo.
4. Successivamente, dovresti trovare e aprire un modulo che non viene utilizzato.
5. Quindi copia e incolla il seguente codice VBA in questa finestra del modulo.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Successivamente, puoi uscire dalla finestra dell'editor VBA corrente e procedere con l'aggiunta della nuova macro alla barra degli strumenti di accesso rapido o alla barra multifunzione della finestra dei messaggi.
7. Successivamente è necessario modificare il livello di sicurezza delle macro di Outlook in basso.
8. Alla fine puoi provare.

• Innanzitutto, crea e componi una nuova email di Outlook come al solito.
• Quindi premi il pulsante macro nella barra degli strumenti di accesso rapido, come l'immagine qui sotto:
• Successivamente ti verrà richiesto di selezionare una cartella Windows di origine e premere "OK".
• Se c'è un file di questo tipo nella cartella Windows selezionata, riceverai un messaggio come il seguente screenshot:
• Quando premi "Sì", questo file verrà allegato immediatamente.

Risolvi i problemi di Outlook il prima possibile

Ogni volta che riscontri problemi con Outlook, si consiglia di risolverli il prima possibile. In questa situazione, faresti meglio a preparare un robusto Correzione di Outlook strumento in anticipo, come ad esempio DataNumen Outlook Repair. È in grado di correggere gli errori PST e salvare i dati di Outlook in modo efficace.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui mdf corrotto e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com