Come mostrare l'età delle persone corrispondenti per tutti gli eventi di compleanno nella visualizzazione elenco del calendario di Outlook

Alcuni utenti vorrebbero vedere anche l'età della persona corrispondente quando visualizzano un evento di compleanno nel calendario. Pertanto, in questo articolo, condivideremo un metodo per realizzare facilmente questa idea.

Quando aggiungi le informazioni sul compleanno a un contatto, Outlook creerà automaticamente un evento di compleanno nel calendario. In questa circostanza, ogni volta che vedi eventi di compleanno nel calendario, potresti anche voler ottenere le età delle persone corrispondenti. Quindi, qui ti presenteremo un modo per realizzarlo.

Mostra l'età delle persone corrispondenti per tutti gli eventi di compleanno nella visualizzazione elenco

1. All'inizio, avvia l'editor VBA di Outlook.
2. Quindi, copia il codice seguente in un modulo.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. Successivamente, posiziona il cursore nella prima subroutine e premi "F5" per eseguire questa macro.
4. Al termine della macro, esci dall'editor VBA e apri una cartella del calendario.
5. Successivamente, vai alla scheda "Visualizza" e fai clic su "Cambia vista" > "Elenco".
6. Successivamente, fai clic sul pulsante "Visualizza impostazioni".
7. Nella finestra di dialogo popup, scegli "Colonne".
8. Quindi, nella finestra di dialogo successiva di "Mostra colonne", seleziona "Campi definiti dall'utente nella cartella" dall'elenco di "Seleziona campi disponibili da".
9. Successivamente, seleziona "Età" nella casella "Colonne disponibili" e fai clic sul pulsante "Aggiungi ->".
10. Alla fine, fai clic su una serie di "OK" fino a tornare all'elenco degli elementi del calendario.
11. Ora, nell'elenco, puoi vedere le età delle persone di tutti gli eventi di compleanno, come mostrato nella figura seguente.

Correggi il file di Outlook compromesso

Potresti farti prendere dal panico durante l'incontro Outlook corrotto file che contiene molte delle tue preziose e-mail e programmi. Nonostante questo problema sia piuttosto disperato, devi comunque calmarti subito e prendere in considerazione misure efficaci. Se ti preoccupi, la situazione può peggiorare sempre di più. In realtà, ci sono diversi modi e utilità che possono riparare il file danneggiato, come lo strumento di riparazione della posta in arrivo e uno strumento più robusto ed esperto, come DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui SQL Server fisso e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com