Come impostare un tempo di promemoria predefinito diverso per diversi tipi di elementi contrassegnati in Outlook

Per impostazione predefinita, Outlook utilizzerà automaticamente l'ora di promemoria predefinita delle attività per tutti i tipi di elementi contrassegnati. Tuttavia, se desideri utilizzare tempi di promemoria diversi per gli articoli contrassegnati in base al tipo di articolo, puoi fare riferimento al metodo introdotto in questo articolo.

Outlook consente di impostare l'ora predefinita del promemoria per tutti gli elementi contrassegnati, indipendentemente dal tipo di elemento. Puoi andare al menu "File" e fare clic su "Opzioni". Quindi, nella finestra "Opzioni di Outlook", puoi vedere l'opzione "Ora promemoria predefinita" nella scheda "Attività", come mostrato nello screenshot seguente.

Tuttavia most gli utenti sperano di utilizzare tempi di promemoria diversi per diversi tipi di elementi contrassegnati, come "9:00" per i messaggi contrassegnati e "17:30" per i contatti contrassegnati. Ora, nel seguito, ci concentreremo su questo esempio per introdurre un metodo.

Imposta un tempo di promemoria predefinito diverso per diversi tipi di articoli contrassegnati

1. A start con, avvia l'applicazione Outlook.
2. Quindi, accedi all'editor VBA di Outlook con riferimento a "Come eseguire il codice VBA in Outlook".
3. Nella successiva finestra "Microsoft Visual Basic for Applications", copiare il seguente codice nel progetto "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Successivamente, ristart Outlook per attivare questa macro.
5. D'ora in poi, ogni volta che contrassegni un'e-mail, l'ora del promemoria sarà impostata su "10:00" alla data di scadenza del contrassegno.
6. E quando contrassegni un contatto, l'ora del promemoria verrà impostata su "17:30" alla data di scadenza del contrassegno.

Affronta i problemi di Outlook in modo flessibile

Puoi incontrare tutti i tipi di problemi nel tuo Outlook. Quindi, devi imparare alcune misure per affrontarli in anticipo. Ad esempio, se il tuo Outlook spesso restarts, devi riparare Office o disabilitare i componenti aggiuntivi di terze parti, ecc. Oppure se il tuo PST di Outlook viene compromesso, puoi prima provare il strumento di riparazione della posta in arrivo. Quando fallisce, puoi continuare a ricorrere a un potente strumento esterno, come DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui recupero mdf e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com