Come utilizzare automaticamente diversi colori dei caratteri per rispondere e inoltrare e-mail con Outlook VBA

Per impostazione predefinita, non è possibile consentire a Outlook di utilizzare automaticamente colori dei caratteri diversi per rispondere e inoltrare le e-mail. Pertanto, se hai tale requisito, puoi leggere questa post per imparare un approccio intelligente.

Outlook consente solo di specificare un carattere utilizzato sia per la risposta che per l'inoltro delle e-mail. Puoi andare su "File" > "Opzioni". Quindi, in "Opzioni di Outlook", passare alla scheda "Posta" e fare clic sul pulsante "Cancelleria e caratteri...". Nella finestra successiva, puoi vedere il pulsante "Carattere" in "Risposta o inoltro di messaggi". Fare clic su di esso, quindi è possibile impostare un colore del carattere specifico per rispondere e inoltrare le e-mail.

Tuttavia, molti utenti sperano di utilizzare colori di carattere diversi per rispondere o inoltrare le e-mail. Sebbene Outlook non fornisca alcuna funzionalità diretta per questo, può comunque essere realizzato con il codice VBA. Ora, continua a leggere per ottenere un tale pezzo di codice VBA.

Usa automaticamente diversi colori dei caratteri per rispondere e inoltrare le e-mail

1. Per cometart, avvia l'applicazione Outlook.
2. Quindi, attiva l'editor VBA con riferimento a "Come eseguire il codice VBA in Outlook".
3. Successivamente, in conformità a “Come aggiungere un oggetto Library Riferimento in VBA“, aggiungere il riferimento a “MS Word Object Library ".
4. Successivamente, copia il seguente codice nel progetto "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Successivamente, ristart Outlook per attivare questa macro.
6. Finalmente puoi provare.

• Seleziona o apri un'e-mail.
• Quindi, fai clic sul pulsante "Rispondi". Nella risposta all'e-mail, puoi digitare alcune parole nel corpo. Il colore del carattere deve essere rosa.
• Oppure fai clic sul pulsante "Rispondi a tutti". Nella nuova posta "rispondi a tutti", inserisci le parole nel corpo. Il colore del carattere è sicuramente verde.
• Allo stesso modo, fai clic sul pulsante "Avanti". Nella mail di inoltro, le nuove parole verranno mostrate in blu.

Ricorri a un software affidabile

In caso di Corruzione di Outlook, Most gli utenti tendono a ricorrere al software di recupero di Outlook. Ci sono una grande quantità di tali programmi disponibili sul mercato. E alcuni di loro sono anche gratuiti. Tuttavia, dovresti stare attento a quelli provenienti da fonti sconosciute in quanto potrebbero peggiorare il caso attuale. Dovresti prendere l'aiuto di uno strumento affidabile ed esperto, come DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui sql corrotto e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com