Come esportare la struttura delle cartelle del file di Outlook in Excel

Se desideri esportare rapidamente la struttura delle cartelle del tuo file di dati di Outlook in una cartella di lavoro di Excel, puoi utilizzare il metodo introdotto in questo articolo.

Per alcuni motivi, come la registrazione delle cartelle e delle sottocartelle correnti di Outlook, molti utenti sperano di esportare la struttura delle cartelle di un file di Outlook in un file esterno, come una cartella di lavoro di Excel. Di seguito, condivideremo un pezzo di codice VBA, che può aiutarti a raggiungerlo in un batter d'occhio.

Esporta la struttura delle cartelle del tuo file di Outlook in Excel

1. A start con, avvia l'applicazione Outlook.
2. Quindi, nella finestra principale di Outlook, premi i pulsanti "Alt + F11".
3. Successivamente, entrerai nell'editor VBA di Outlook, in cui dovresti aprire un modulo inutilizzato.
4. Successivamente, puoi copiare il seguente codice VBA in questo modulo.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Successivamente, dovresti assicurarti che Outlook abbia abilitato le macro.
6. Alla fine, puoi fare uno scatto:

• Nella finestra macro corrente, premere il tasto F5.
• Al termine della macro, riceverai un avviso che richiede "Completato".
• Successivamente, puoi andare alla cartella locale predefinita per trovare un nuovo file Excel. Aprilo e apparirà come il seguente screenshot:

Non ignorare mai eventuali errori di Outlook

Nonostante la quantità di funzionalità, Outlook è lo stesso suscettibile di errori e corruzione di altri client di posta elettronica. Pertanto, dovresti attribuire importanza a tutti gli errori nel tuo Outlook. Non trascurarli, per favore. In caso contrario, l'accumulo di errori può portare alla corruzione di Outlook alla fine. Se ci si trova di fronte a errori complessi, si suggerisce di utilizzare uno strumento potente, come ad esempio DataNumen Outlook Repair, Che può riparare Outlook errori in pochi secondi.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui ripristino sql e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com